nordic-dev.net/nixpkgs
nordic-dev.net/nixpkgs
2
0
Fork 0
mirror of https://github.com/NixOS/nixpkgs.git synced 2025-02-20 19:16:11 +00:00
Code Issues Packages Projects Releases Wiki Activity

prometheus-php-fpm-exporter: init at 2.2.0

Browse Source
This commit is contained in:
Gaël Reyrol 2023-06-28 20:55:46 +02:00
parent e5f1b02bd5
commit 28fb612abc
No known key found for this signature in database
GPG Key ID: DFB9B69A2C427F61
2 changed files with 60 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

59
pkgs/servers/monitoring/prometheus/php-fpm-exporter.nix Normal file
View File

@ -0,0 +1,59 @@
{ lib
, buildGoModule
, fetchFromGitHub
, makeWrapper
, installShellFiles
, getent
, nix-update-script
, testers
, prometheus-php-fpm-exporter
}:
buildGoModule rec {
pname = "php-fpm_exporter";
version = "2.2.0";
src = fetchFromGitHub {
owner = "hipages";
repo = pname;
rev = "v${version}";
hash = "sha256-ggrFnyEdGBoZVh4dHMw+7RUm8nJ1hJXo/fownO3wvzE=";
};
vendorHash = "sha256-OK36tHkBtosdfEWFPYMtlbzCkh5cF35NBWYyJrb9fwg= ";
nativeBuildInputs = [ makeWrapper installShellFiles ];
ldflags = [
"-X main.version=${version}"
];
preFixup = ''
wrapProgram "$out/bin/php-fpm_exporter" \
--prefix PATH ":" "${lib.makeBinPath [ getent ]}"
'';
postInstall = ''
installShellCompletion --cmd php-fpm_exporter \
--bash <($out/bin/php-fpm_exporter completion bash) \
--fish <($out/bin/php-fpm_exporter completion fish) \
--zsh <($out/bin/php-fpm_exporter completion zsh)
'';
passthru = {
updateScript = nix-update-script { };
tests = testers.testVersion {
inherit version;
package = prometheus-php-fpm-exporter;
command = "php-fpm_exporter version";
};
};
meta = with lib; {
homepage = "https://github.com/hipages/php-fpm_exporter";
description = "A prometheus exporter for PHP-FPM.";
license = licenses.asl20;
maintainers = with maintainers; [ gaelreyrol ];
mainProgram = "php-fpm_exporter";
};
}

1
pkgs/top-level/all-packages.nix
View File

@ -26483,6 +26483,7 @@ with pkgs;
prometheus-nut-exporter = callPackage ../servers/monitoring/prometheus/nut-exporter.nix { };
prometheus-openldap-exporter = callPackage ../servers/monitoring/prometheus/openldap-exporter.nix { } ;
prometheus-openvpn-exporter = callPackage ../servers/monitoring/prometheus/openvpn-exporter.nix { };
prometheus-php-fpm-exporter = callPackage ../servers/monitoring/prometheus/php-fpm-exporter.nix { };
prometheus-pihole-exporter = callPackage ../servers/monitoring/prometheus/pihole-exporter.nix { };
prometheus-postfix-exporter = callPackage ../servers/monitoring/prometheus/postfix-exporter.nix { };
prometheus-postgres-exporter = callPackage ../servers/monitoring/prometheus/postgres-exporter.nix { };