From 28fb612abc4fcc7e5c460c8e94dc03fb748b3e13 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Ga=C3=ABl=20Reyrol?= <me@gaelreyrol.dev>
Date: Wed, 28 Jun 2023 20:55:46 +0200
Subject: [PATCH] prometheus-php-fpm-exporter: init at 2.2.0

---
 .../prometheus/php-fpm-exporter.nix           | 59 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  1 +
 2 files changed, 60 insertions(+)
 create mode 100644 pkgs/servers/monitoring/prometheus/php-fpm-exporter.nix

diff --git a/pkgs/servers/monitoring/prometheus/php-fpm-exporter.nix b/pkgs/servers/monitoring/prometheus/php-fpm-exporter.nix
new file mode 100644
index 000000000000..e9ba97d1f3f7
--- /dev/null
+++ b/pkgs/servers/monitoring/prometheus/php-fpm-exporter.nix
@@ -0,0 +1,59 @@
+{ lib
+, buildGoModule
+, fetchFromGitHub
+, makeWrapper
+, installShellFiles
+, getent
+, nix-update-script
+, testers
+, prometheus-php-fpm-exporter
+}:
+
+buildGoModule rec {
+  pname = "php-fpm_exporter";
+  version = "2.2.0";
+
+  src = fetchFromGitHub {
+    owner = "hipages";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-ggrFnyEdGBoZVh4dHMw+7RUm8nJ1hJXo/fownO3wvzE=";
+  };
+
+  vendorHash = "sha256-OK36tHkBtosdfEWFPYMtlbzCkh5cF35NBWYyJrb9fwg= ";
+
+  nativeBuildInputs = [ makeWrapper installShellFiles ];
+
+  ldflags = [
+    "-X main.version=${version}"
+  ];
+
+  preFixup = ''
+    wrapProgram "$out/bin/php-fpm_exporter" \
+      --prefix PATH ":" "${lib.makeBinPath [ getent ]}"
+  '';
+
+  postInstall = ''
+    installShellCompletion --cmd php-fpm_exporter \
+      --bash <($out/bin/php-fpm_exporter completion bash) \
+      --fish <($out/bin/php-fpm_exporter completion fish) \
+      --zsh <($out/bin/php-fpm_exporter completion zsh)
+  '';
+
+  passthru = {
+    updateScript = nix-update-script { };
+    tests = testers.testVersion {
+      inherit version;
+      package = prometheus-php-fpm-exporter;
+      command = "php-fpm_exporter version";
+    };
+  };
+
+  meta = with lib; {
+    homepage = "https://github.com/hipages/php-fpm_exporter";
+    description = "A prometheus exporter for PHP-FPM.";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ gaelreyrol ];
+    mainProgram = "php-fpm_exporter";
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 84869bc10e39..75e001c7e5b6 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -26483,6 +26483,7 @@ with pkgs;
   prometheus-nut-exporter = callPackage ../servers/monitoring/prometheus/nut-exporter.nix { };
   prometheus-openldap-exporter = callPackage ../servers/monitoring/prometheus/openldap-exporter.nix { } ;
   prometheus-openvpn-exporter = callPackage ../servers/monitoring/prometheus/openvpn-exporter.nix { };
+  prometheus-php-fpm-exporter = callPackage ../servers/monitoring/prometheus/php-fpm-exporter.nix { };
   prometheus-pihole-exporter = callPackage ../servers/monitoring/prometheus/pihole-exporter.nix {  };
   prometheus-postfix-exporter = callPackage ../servers/monitoring/prometheus/postfix-exporter.nix { };
   prometheus-postgres-exporter = callPackage ../servers/monitoring/prometheus/postgres-exporter.nix { };