mirror of
https://gitlab.freedesktop.org/wlroots/wlroots.git
synced 2024-11-22 07:02:28 +00:00
471b873de3
The keyboard shortcuts inhibitor protocol is useful for remote desktop and virtualization software in order to request all keyboard events to be passed to it and (almost) none being resonded to by the compositor. This allows the session at the other end of the remote desktop connection or inside the virtual machine to be interacted with as usual (e.g. Alt+Tab to switch windows on the remote system instead of locally). Add the wayland protocol to the meson build files. Copy'n'search'n'replace the very similar idle inhibit protocol implementation. This already provides all the basic functionality: - creating and destroying inhibitors upon request by a client, - destruction in reaction to destruction of surfaces or displays, - a list of inhibitors to search through for existing ones as well as - a signal to be sent to the compositor upon registration of a new inhibitor. Beyond that we add the active and inactive events to be sent to the client and wire those to activate and deactivate functions for the compositor to call in confirmation of activation of a new inhibitor or (un-)suspending of an existing inhibitor e.g. in response to a special key combination entered by the user as suggested by the protocol. As mandated by the protocol, we check the existance of an inhibitor for a given surface and seat upon creation and return the error provided by the protocol for that purpose. Signed-off-by: Michael Weiser <michael.weiser@gmx.de> Closes: https://github.com/swaywm/wlroots/issues/1817
78 lines
3.8 KiB
Meson
78 lines
3.8 KiB
Meson
wl_protocol_dir = wayland_protos.get_variable(pkgconfig: 'pkgdatadir')
|
|
|
|
wayland_scanner_dep = dependency('wayland-scanner', required: false, native: true)
|
|
if wayland_scanner_dep.found()
|
|
wayland_scanner = find_program(
|
|
wayland_scanner_dep.get_variable(pkgconfig: 'wayland_scanner'),
|
|
native: true,
|
|
)
|
|
else
|
|
wayland_scanner = find_program('wayland-scanner', native: true)
|
|
endif
|
|
|
|
protocols = {
|
|
# Stable upstream protocols
|
|
'xdg-shell': wl_protocol_dir / 'stable/xdg-shell/xdg-shell.xml',
|
|
'presentation-time': wl_protocol_dir / 'stable/presentation-time/presentation-time.xml',
|
|
# Unstable upstream protocols
|
|
'fullscreen-shell-unstable-v1': wl_protocol_dir / 'unstable/fullscreen-shell/fullscreen-shell-unstable-v1.xml',
|
|
'idle-inhibit-unstable-v1': wl_protocol_dir / 'unstable/idle-inhibit/idle-inhibit-unstable-v1.xml',
|
|
'keyboard-shortcuts-inhibit-unstable-v1': wl_protocol_dir / 'unstable/keyboard-shortcuts-inhibit/keyboard-shortcuts-inhibit-unstable-v1.xml',
|
|
'linux-dmabuf-unstable-v1': wl_protocol_dir / 'unstable/linux-dmabuf/linux-dmabuf-unstable-v1.xml',
|
|
'pointer-constraints-unstable-v1': wl_protocol_dir / 'unstable/pointer-constraints/pointer-constraints-unstable-v1.xml',
|
|
'pointer-gestures-unstable-v1': wl_protocol_dir / 'unstable/pointer-gestures/pointer-gestures-unstable-v1.xml',
|
|
'primary-selection-unstable-v1': wl_protocol_dir / 'unstable/primary-selection/primary-selection-unstable-v1.xml',
|
|
'relative-pointer-unstable-v1': wl_protocol_dir / 'unstable/relative-pointer/relative-pointer-unstable-v1.xml',
|
|
'tablet-unstable-v2': wl_protocol_dir / 'unstable/tablet/tablet-unstable-v2.xml',
|
|
'text-input-unstable-v3': wl_protocol_dir / 'unstable/text-input/text-input-unstable-v3.xml',
|
|
'xdg-decoration-unstable-v1': wl_protocol_dir / 'unstable/xdg-decoration/xdg-decoration-unstable-v1.xml',
|
|
'xdg-output-unstable-v1': wl_protocol_dir / 'unstable/xdg-output/xdg-output-unstable-v1.xml',
|
|
'xdg-shell-unstable-v6': wl_protocol_dir / 'unstable/xdg-shell/xdg-shell-unstable-v6.xml',
|
|
# Other protocols
|
|
'gtk-primary-selection': 'gtk-primary-selection.xml',
|
|
'kde-idle': 'idle.xml',
|
|
'kde-server-decoration': 'server-decoration.xml',
|
|
'input-method-unstable-v2': 'input-method-unstable-v2.xml',
|
|
'virtual-keyboard-unstable-v1': 'virtual-keyboard-unstable-v1.xml',
|
|
'wlr-data-control-unstable-v1': 'wlr-data-control-unstable-v1.xml',
|
|
'wlr-export-dmabuf-unstable-v1': 'wlr-export-dmabuf-unstable-v1.xml',
|
|
'wlr-foreign-toplevel-management-unstable-v1': 'wlr-foreign-toplevel-management-unstable-v1.xml',
|
|
'wlr-gamma-control-unstable-v1': 'wlr-gamma-control-unstable-v1.xml',
|
|
'wlr-input-inhibitor-unstable-v1': 'wlr-input-inhibitor-unstable-v1.xml',
|
|
'wlr-layer-shell-unstable-v1': 'wlr-layer-shell-unstable-v1.xml',
|
|
'wlr-output-management-unstable-v1': 'wlr-output-management-unstable-v1.xml',
|
|
'wlr-output-power-management-unstable-v1': 'wlr-output-power-management-unstable-v1.xml',
|
|
'wlr-screencopy-unstable-v1': 'wlr-screencopy-unstable-v1.xml',
|
|
'wlr-virtual-pointer-unstable-v1': 'wlr-virtual-pointer-unstable-v1.xml',
|
|
}
|
|
|
|
foreach name, path : protocols
|
|
code = custom_target(
|
|
name.underscorify() + '_c',
|
|
input: path,
|
|
output: '@BASENAME@-protocol.c',
|
|
command: [wayland_scanner, 'private-code', '@INPUT@', '@OUTPUT@'],
|
|
)
|
|
wlr_files += code
|
|
|
|
server_header = custom_target(
|
|
name.underscorify() + '_server_h',
|
|
input: path,
|
|
output: '@BASENAME@-protocol.h',
|
|
command: [wayland_scanner, 'server-header', '@INPUT@', '@OUTPUT@'],
|
|
)
|
|
wlr_files += server_header
|
|
|
|
client_header = custom_target(
|
|
name.underscorify() + '_client_h',
|
|
input: path,
|
|
output: '@BASENAME@-client-protocol.h',
|
|
command: [wayland_scanner, 'client-header', '@INPUT@', '@OUTPUT@'],
|
|
build_by_default: false,
|
|
)
|
|
|
|
set_variable(name.underscorify() + '_c', code)
|
|
set_variable(name.underscorify() + '_server_h', server_header)
|
|
set_variable(name.underscorify() + '_client_h', client_header)
|
|
endforeach
|