mirror of
https://gitlab.freedesktop.org/wlroots/wlroots.git
synced 2024-11-22 23:22:24 +00:00
52 lines
1.2 KiB
Meson
52 lines
1.2 KiB
Meson
wl_protocol_dir = wayland_protos.get_pkgconfig_variable('pkgdatadir')
|
|
|
|
wayland_scanner = find_program('wayland-scanner')
|
|
|
|
wayland_scanner_server = generator(
|
|
wayland_scanner,
|
|
output: '@BASENAME@-protocol.h',
|
|
arguments: ['server-header', '@INPUT@', '@OUTPUT@'],
|
|
)
|
|
|
|
wayland_scanner_code = generator(
|
|
wayland_scanner,
|
|
output: '@BASENAME@-protocol.c',
|
|
arguments: ['code', '@INPUT@', '@OUTPUT@'],
|
|
)
|
|
|
|
wayland_scanner_client = generator(
|
|
wayland_scanner,
|
|
output: '@BASENAME@-client-protocol.h',
|
|
arguments: ['client-header', '@INPUT@', '@OUTPUT@'],
|
|
)
|
|
|
|
protocols = [
|
|
[wl_protocol_dir, 'unstable/xdg-shell/xdg-shell-unstable-v6.xml'],
|
|
'gamma-control.xml'
|
|
]
|
|
|
|
client_protocols = [
|
|
[wl_protocol_dir, 'unstable/xdg-shell/xdg-shell-unstable-v6.xml']
|
|
]
|
|
|
|
wl_protos_src = []
|
|
wl_protos_headers = []
|
|
|
|
foreach p : protocols
|
|
xml = join_paths(p)
|
|
wl_protos_src += wayland_scanner_code.process(xml)
|
|
wl_protos_headers += wayland_scanner_server.process(xml)
|
|
endforeach
|
|
|
|
foreach p : client_protocols
|
|
xml = join_paths(p)
|
|
wl_protos_headers += wayland_scanner_client.process(xml)
|
|
endforeach
|
|
|
|
lib_wl_protos = static_library('wl_protos', wl_protos_src + wl_protos_headers)
|
|
|
|
wlr_protos = declare_dependency(
|
|
link_with: lib_wl_protos,
|
|
sources: wl_protos_headers,
|
|
)
|