mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-24 16:03:23 +00:00
fd78240ac8
At some point, I'd like to make another attempt at71f1f4884b("openssl: stop static binaries referencing libs"), which was reverted in195c7da07d. One problem with my previous attempt is that I moved OpenSSL's libraries to a lib output, but many dependent packages were hardcoding the out output as the location of the libraries. This patch fixes every such case I could find in the tree. It won't have any effect immediately, but will mean these packages will automatically use an OpenSSL lib output if it is reintroduced in future. This patch should cause very few rebuilds, because it shouldn't make any change at all to most packages I'm touching. The few rebuilds that are introduced come from when I've changed a package builder not to use variable names like openssl.out in scripts / substitution patterns, which would be confusing since they don't hardcode the output any more. I started by making the following global replacements: ${pkgs.openssl.out}/lib -> ${lib.getLib pkgs.openssl}/lib ${openssl.out}/lib -> ${lib.getLib openssl}/lib Then I removed the ".out" suffix when part of the argument to lib.makeLibraryPath, since that function uses lib.getLib internally. Then I fixed up cases where openssl was part of the -L flag to the compiler/linker, since that unambigously is referring to libraries. Then I manually investigated and fixed the following packages: - pycurl - citrix-workspace - ppp - wraith - unbound - gambit - acl2 I'm reasonably confindent in my fixes for all of them. For acl2, since the openssl library paths are manually provided above anyway, I don't think openssl is required separately as a build input at all. Removing it doesn't make a difference to the output size, the file list, or the closure. I've tested evaluation with the OfBorg meta checks, to protect against introducing evaluation failures.
72 lines
2.3 KiB
Nix
72 lines
2.3 KiB
Nix
{ lib, stdenv, fetchurl, fetchpatch, autoreconfHook, removeReferencesTo
|
|
, file, openssl, perl, perlPackages, nettools, gnused
|
|
, withPerlTools ? false }: let
|
|
|
|
perlWithPkgs = perl.withPackages (ps: with ps; [
|
|
JSON
|
|
TermReadKey
|
|
Tk
|
|
]);
|
|
|
|
in stdenv.mkDerivation rec {
|
|
pname = "net-snmp";
|
|
version = "5.9.1";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/net-snmp/${pname}-${version}.tar.gz";
|
|
sha256 = "sha256-63/UpE3mzdv/2akqha0TCeXBBU+51afdkweciVP0jD8=";
|
|
};
|
|
|
|
patches =
|
|
let fetchAlpinePatch = name: sha256: fetchpatch {
|
|
url = "https://git.alpinelinux.org/aports/plain/main/net-snmp/${name}?id=f25d3fb08341b60b6ccef424399f060dfcf3f1a5";
|
|
inherit name sha256;
|
|
};
|
|
in [
|
|
(fetchAlpinePatch "fix-includes.patch" "0zpkbb6k366qpq4dax5wknwprhwnhighcp402mlm7950d39zfa3m")
|
|
(fetchAlpinePatch "netsnmp-swinst-crash.patch" "0gh164wy6zfiwiszh58fsvr25k0ns14r3099664qykgpmickkqid")
|
|
];
|
|
|
|
outputs = [ "bin" "out" "dev" "lib" ];
|
|
|
|
configureFlags =
|
|
[ "--with-default-snmp-version=3"
|
|
"--with-sys-location=Unknown"
|
|
"--with-sys-contact=root@unknown"
|
|
"--with-logfile=/var/log/net-snmpd.log"
|
|
"--with-persistent-directory=/var/lib/net-snmp"
|
|
"--with-openssl=${openssl.dev}"
|
|
"--disable-embedded-perl"
|
|
"--without-perl-modules"
|
|
] ++ lib.optional stdenv.isLinux "--with-mnttab=/proc/mounts";
|
|
|
|
postPatch = ''
|
|
substituteInPlace testing/fulltests/support/simple_TESTCONF.sh --replace "/bin/netstat" "${nettools}/bin/netstat"
|
|
'';
|
|
|
|
nativeBuildInputs = [ autoreconfHook nettools removeReferencesTo gnused file ];
|
|
buildInputs = [ openssl ]
|
|
++ lib.optional withPerlTools perlWithPkgs;
|
|
|
|
enableParallelBuilding = true;
|
|
doCheck = false; # tries to use networking
|
|
|
|
postInstall = ''
|
|
for f in "$lib/lib/"*.la $bin/bin/net-snmp-config $bin/bin/net-snmp-create-v3-user; do
|
|
sed 's|-L${openssl.dev}|-L${lib.getLib openssl}|g' -i $f
|
|
done
|
|
mkdir $dev/bin
|
|
mv $bin/bin/net-snmp-config $dev/bin
|
|
# libraries contain configure options
|
|
find $lib/lib -type f -exec remove-references-to -t $bin '{}' +
|
|
find $lib/lib -type f -exec remove-references-to -t $dev '{}' +
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Clients and server for the SNMP network monitoring protocol";
|
|
homepage = "http://www.net-snmp.org/";
|
|
license = licenses.bsd3;
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|