mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-02 19:14:14 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
48 lines
1.3 KiB
Nix
48 lines
1.3 KiB
Nix
{ fetchurl, lib, stdenv, autoreconfHook, curl }:
|
|
|
|
let
|
|
major = "2";
|
|
minor = "22";
|
|
in stdenv.mkDerivation rec {
|
|
pname = "dirb";
|
|
version = "${major}.${minor}";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/dirb/${version}/dirb${major}${minor}.tar.gz";
|
|
sha256 = "0b7wc2gvgnyp54rxf1n9arn6ymrvdb633v6b3ah138hw4gg8lx7k";
|
|
};
|
|
|
|
nativeBuildInputs = [ autoreconfHook ];
|
|
buildInputs = [ curl ];
|
|
|
|
unpackPhase = ''
|
|
tar -xf $src
|
|
find . -exec chmod +x "{}" ";"
|
|
export sourceRoot="dirb222"
|
|
'';
|
|
|
|
postPatch = ''
|
|
sed -i "s#/usr#$out#" src/dirb.c
|
|
'';
|
|
|
|
# Workaround build failure on -fno-common toolchains like upstream
|
|
# gcc-10. Otherwise build fails as:
|
|
# ld: resume.o:/build/dirb222/src/variables.h:15: multiple definition of `curl';
|
|
# crea_wordlist.o:/build/dirb222/src/variables.h:15: first defined here
|
|
env.NIX_CFLAGS_COMPILE = "-fcommon";
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/share/{dirb,wordlists}
|
|
cp -r wordlists/ $out/share/dirb/
|
|
ln -s $out/share/dirb/wordlists/ $out/share/wordlists/dirb
|
|
'';
|
|
|
|
meta = {
|
|
description = "Web content scanner";
|
|
homepage = "https://dirb.sourceforge.net/";
|
|
maintainers = with lib.maintainers; [ bennofs ];
|
|
license = with lib.licenses; [ gpl2Only ];
|
|
platforms = lib.platforms.unix;
|
|
};
|
|
}
|