mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-21 12:23:55 +00:00
c6132dcf23
Upstream `gcc-13` merged `mcfgthreads` support with a caveat: it's
headers interface is not compatible with the patch `nixpkgs` was
carrying in `gcc-12` and before.
To keep both new (`gcc13`) and old (`_pre_gcc13`) version I held back
previous `windows.mcfgthreads` attribute as
`windows.mcfgthreads_pre_gcc_13`. It is used for `gcc` before 13.
The change fixes the build of `pkgsCross.mingwW64.stdenv` itself and
example program:
$ nix build --impure --expr 'with import ./. {}; pkgsCross.mingwW64.re2c.override { stdenv = pkgsCross.mingwW64.gcc11Stdenv; }'
49 lines
1.5 KiB
Nix
49 lines
1.5 KiB
Nix
{ lib
|
|
, stdenvNoCC
|
|
, fetchFromGitHub
|
|
, pkgsCross
|
|
, stdenv
|
|
, bash
|
|
}:
|
|
|
|
stdenvNoCC.mkDerivation (finalAttrs:
|
|
let
|
|
dxvk32 = if stdenv.isDarwin then pkgsCross.mingw32.dxvk_1 else pkgsCross.mingw32.dxvk_2;
|
|
dxvk64 = if stdenv.isDarwin then pkgsCross.mingwW64.dxvk_1 else pkgsCross.mingwW64.dxvk_2;
|
|
in
|
|
{
|
|
pname = "dxvk";
|
|
inherit (dxvk64) version;
|
|
|
|
outputs = [ "out" "bin" "lib" ];
|
|
|
|
dontUnpack = true;
|
|
dontConfigure = true;
|
|
dontBuild = true;
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/bin $bin $lib
|
|
substitute ${./setup_dxvk.sh} $out/bin/setup_dxvk.sh \
|
|
--subst-var-by bash ${bash} \
|
|
--subst-var-by dxvk32 ${dxvk32} \
|
|
--subst-var-by dxvk64 ${dxvk64} \
|
|
--subst-var-by mcfgthreads32 "${pkgsCross.mingw32.windows.mcfgthreads_pre_gcc_13}" \
|
|
--subst-var-by mcfgthreads64 "${pkgsCross.mingwW64.windows.mcfgthreads_pre_gcc_13}"
|
|
chmod a+x $out/bin/setup_dxvk.sh
|
|
declare -A dxvks=( [x32]=${dxvk32} [x64]=${dxvk64} )
|
|
for arch in "''${!dxvks[@]}"; do
|
|
ln -s "''${dxvks[$arch]}/bin" $bin/$arch
|
|
ln -s "''${dxvks[$arch]}/lib" $lib/$arch
|
|
done
|
|
'';
|
|
|
|
meta = {
|
|
description = "Setup script for DXVK";
|
|
homepage = "https://github.com/doitsujin/dxvk";
|
|
changelog = "https://github.com/doitsujin/dxvk/releases";
|
|
maintainers = [ lib.maintainers.reckenrode ];
|
|
license = lib.licenses.zlib;
|
|
platforms = [ "x86_64-darwin" "i686-linux" "x86_64-linux" ];
|
|
};
|
|
})
|