mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-08 22:14:34 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
77 lines
1.7 KiB
Nix
77 lines
1.7 KiB
Nix
{ lib, stdenv, fetchFromGitHub
|
|
, asciidoctor, autoreconfHook, pkg-config
|
|
, boost, libctemplate, libmaxminddb, libpcap, libtins, openssl, protobuf, xz, zlib, catch2
|
|
, cbor-diag, cddl, diffutils, file, mktemp, netcat, tcpdump, wireshark-cli
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "compactor";
|
|
version = "1.2.3";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "dns-stats";
|
|
repo = "compactor";
|
|
rev = version;
|
|
fetchSubmodules = true;
|
|
hash = "sha256-5Z14suhO5ghhmZsSj4DsSoKm+ct2gQFO6qxhjmx4Xm4=";
|
|
};
|
|
|
|
patches = [
|
|
./patches/add-a-space-after-type-in-check-response-opt-sh.patch
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
asciidoctor
|
|
autoreconfHook
|
|
pkg-config
|
|
];
|
|
buildInputs = [
|
|
boost
|
|
libctemplate
|
|
libmaxminddb
|
|
libpcap
|
|
libtins
|
|
openssl
|
|
protobuf
|
|
xz
|
|
zlib
|
|
];
|
|
|
|
postPatch = ''
|
|
patchShebangs test-scripts/
|
|
cp ${catch2}/include/catch2/catch.hpp tests/catch.hpp
|
|
'';
|
|
|
|
preConfigure = ''
|
|
substituteInPlace configure \
|
|
--replace "/usr/bin/file" "${file}/bin/file"
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--with-boost-libdir=${boost.out}/lib"
|
|
"--with-boost=${boost.dev}"
|
|
];
|
|
enableParallelBuilding = true;
|
|
|
|
doCheck = !stdenv.hostPlatform.isDarwin; # check-dnstap.sh failing on Darwin
|
|
nativeCheckInputs = [
|
|
cbor-diag
|
|
cddl
|
|
diffutils
|
|
file
|
|
mktemp
|
|
netcat
|
|
tcpdump
|
|
wireshark-cli
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Tools to capture DNS traffic and record it in C-DNS files";
|
|
homepage = "https://dns-stats.org/";
|
|
changelog = "https://github.com/dns-stats/compactor/raw/${version}/ChangeLog.txt";
|
|
license = licenses.mpl20;
|
|
maintainers = with maintainers; [ fdns ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|