mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-20 04:33:57 +00:00
9833d56c24
Done with the help of https://github.com/Mindavi/nixpkgs-mark-broken Tool is still WIP but this is one of the first results. I manually audited the results and removed some results that were not valid. Note that some of these packages maybe should have more constrained platforms set instead of broken set, but I think not being perfectly correct is better than just keep trying to build all these things and never succeeding. Some observations: - Some darwin builds require XCode tools - aarch64-linux builds sometimes suffer from using gcc9 - gcc9 is getting older and misses some new libraries/features - Sometimes tools try to do system detection or expect some explicit settings for platforms that are not x86_64-linux
44 lines
1.5 KiB
Nix
44 lines
1.5 KiB
Nix
{ stdenv, lib, fetchurl, alsa-lib, bison, flex, libsndfile, which
|
|
, AppKit, Carbon, CoreAudio, CoreMIDI, CoreServices, Kernel
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "1.4.1.0";
|
|
pname = "chuck";
|
|
|
|
src = fetchurl {
|
|
url = "http://chuck.cs.princeton.edu/release/files/chuck-${version}.tgz";
|
|
sha256 = "sha256-dL+ZrVFeMRPFW4MxUpNvrQKjzwBqVBBf8Rd3xHMZSSg=";
|
|
};
|
|
|
|
nativeBuildInputs = [ flex bison which ];
|
|
|
|
buildInputs = [ libsndfile ]
|
|
++ lib.optional (!stdenv.isDarwin) alsa-lib
|
|
++ lib.optionals stdenv.isDarwin [ AppKit Carbon CoreAudio CoreMIDI CoreServices Kernel ];
|
|
|
|
patches = [ ./darwin-limits.patch ];
|
|
|
|
NIX_CFLAGS_COMPILE = lib.optionalString stdenv.isDarwin "-Wno-missing-sysroot";
|
|
NIX_LDFLAGS = lib.optionalString stdenv.isDarwin "-framework MultitouchSupport";
|
|
|
|
postPatch = ''
|
|
substituteInPlace src/core/makefile.x/makefile.osx \
|
|
--replace "weak_framework" "framework" \
|
|
--replace "MACOSX_DEPLOYMENT_TARGET=10.9" "MACOSX_DEPLOYMENT_TARGET=$MACOSX_DEPLOYMENT_TARGET"
|
|
'';
|
|
|
|
makeFlags = [ "-C src" "DESTDIR=$(out)/bin" ];
|
|
buildFlags = [ (if stdenv.isDarwin then "osx" else "linux-alsa") ];
|
|
|
|
meta = with lib; {
|
|
description = "Programming language for real-time sound synthesis and music creation";
|
|
homepage = "http://chuck.cs.princeton.edu";
|
|
license = licenses.gpl2;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ ftrvxmtrx ];
|
|
# never built on aarch64-darwin since first introduction in nixpkgs
|
|
broken = stdenv.isDarwin && stdenv.isAarch64;
|
|
};
|
|
}
|