mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-02-20 19:16:11 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
59 lines
1.4 KiB
Nix
59 lines
1.4 KiB
Nix
{ lib, stdenv
|
|
, fetchurl
|
|
, makeWrapper
|
|
, curl
|
|
, espeak
|
|
, file
|
|
, gtk3
|
|
, gtkdatabox
|
|
, intltool
|
|
, pkg-config
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "klavaro";
|
|
version = "3.14";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/klavaro/${pname}-${version}.tar.bz2";
|
|
hash = "sha256-hxh+SdMBxRDmlkCYzbYSEmvwMNKodf15nq3K0+rlbas=";
|
|
};
|
|
|
|
nativeBuildInputs = [ intltool makeWrapper pkg-config ];
|
|
buildInputs = [ curl gtk3 gtkdatabox ];
|
|
|
|
postPatch = ''
|
|
substituteInPlace src/tutor.c --replace '"espeak ' '"${espeak}/bin/espeak '
|
|
'';
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/klavaro \
|
|
--prefix LD_LIBRARY_PATH : $out/lib
|
|
'';
|
|
|
|
# Fixes /usr/bin/file: No such file or directory
|
|
preConfigure = ''
|
|
substituteInPlace configure \
|
|
--replace "/usr/bin/file" "${file}/bin/file"
|
|
'';
|
|
|
|
# remove forbidden references to $TMPDIR
|
|
preFixup = lib.optionalString stdenv.hostPlatform.isLinux ''
|
|
for f in "$out"/bin/*; do
|
|
if isELF "$f"; then
|
|
patchelf --shrink-rpath --allowed-rpath-prefixes "$NIX_STORE" "$f"
|
|
fi
|
|
done
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Free touch typing tutor program";
|
|
mainProgram = "klavaro";
|
|
homepage = "http://klavaro.sourceforge.net/";
|
|
changelog = "https://sourceforge.net/p/klavaro/code/HEAD/tree/trunk/ChangeLog";
|
|
license = licenses.gpl3Plus;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ mimame davidak ];
|
|
};
|
|
}
|