mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-02-23 04:25:14 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
50 lines
1.3 KiB
Nix
50 lines
1.3 KiB
Nix
{ lib, stdenv, fetchFromGitHub, fontforge, python3 }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "rictydiminished-with-firacode";
|
|
version = "1.2.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "hakatashi";
|
|
repo = "RictyDiminished-with-FiraCode";
|
|
rev = version;
|
|
hash = "sha256-twh3yLAM4MUjWzSDNmo8gNIRf01hieXeOS334sNdFk4=";
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
postPatch = ''
|
|
# Make builds more reproducible
|
|
substituteInPlace apply-feature.py --replace \
|
|
'ricty = ttLib.TTFont(options.in_font)' \
|
|
'ricty = ttLib.TTFont(options.in_font, recalcTimestamp=False)'
|
|
substituteInPlace build.py --replace \
|
|
'datetime.date.today()' \
|
|
'datetime.date.fromtimestamp(float(os.environ["SOURCE_DATE_EPOCH"]))'
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
install -m444 -Dt $out/share/fonts/rictydiminished-with-firacode *.ttf
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
nativeBuildInputs = [
|
|
(python3.withPackages (ps: [
|
|
ps.jinja2
|
|
ps.fonttools
|
|
ps.fontforge
|
|
]))
|
|
];
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/hakatashi/RictyDiminished-with-FiraCode";
|
|
description = "Best Japanese programming font meets the awesome ligatures of Firacode";
|
|
license = licenses.ofl;
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; [ mt-caret ];
|
|
};
|
|
}
|
|
|