mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-02-20 19:16:11 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
59 lines
1.5 KiB
Nix
59 lines
1.5 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, installShellFiles }:
|
|
|
|
buildGoModule rec {
|
|
pname = "dyff";
|
|
version = "1.9.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "homeport";
|
|
repo = "dyff";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-y5gep3v+totupFbsAuGhySUbcESmQeGHWteQFFXj2Kw=";
|
|
};
|
|
|
|
vendorHash = "sha256-cRPAjFVvjCgT+m8ceAQJt5ZE8ax7jefzdVWPGM45LpY=";
|
|
|
|
subPackages = [
|
|
"cmd/dyff"
|
|
"pkg/dyff"
|
|
"internal/cmd"
|
|
];
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
# test fails with the injected version
|
|
postPatch = ''
|
|
substituteInPlace internal/cmd/cmds_test.go \
|
|
--replace "version (development)" ${version}
|
|
'';
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
"-X=github.com/homeport/dyff/internal/cmd.version=${version}"
|
|
];
|
|
|
|
postInstall = ''
|
|
installShellCompletion --cmd dyff \
|
|
--bash <($out/bin/dyff completion bash) \
|
|
--fish <($out/bin/dyff completion fish) \
|
|
--zsh <($out/bin/dyff completion zsh)
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Diff tool for YAML files, and sometimes JSON";
|
|
mainProgram = "dyff";
|
|
longDescription = ''
|
|
dyff is inspired by the way the old BOSH v1 deployment output reported
|
|
changes from one version to another by only showing the parts of a YAML
|
|
file that change.
|
|
|
|
Each difference is referenced by its location in the YAML document by
|
|
using either the Spruce or go-patch path syntax.
|
|
'';
|
|
homepage = "https://github.com/homeport/dyff";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ edlimerkaj jceb ];
|
|
};
|
|
}
|