mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-02-22 03:53:47 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
66 lines
1.9 KiB
Nix
66 lines
1.9 KiB
Nix
{ lib, stdenv, fetchFromGitHub, autoreconfHook, pkg-config, zlib, readline, openssl
|
|
, libiconv, pcsclite, libassuan, libXt
|
|
, docbook_xsl, libxslt, docbook_xml_dtd_412
|
|
, Carbon, PCSC, buildPackages
|
|
, withApplePCSC ? stdenv.hostPlatform.isDarwin
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "opensc";
|
|
version = "0.25.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "OpenSC";
|
|
repo = "OpenSC";
|
|
rev = version;
|
|
sha256 = "sha256-Ktvp/9Hca87qWmDlQhFzvWsr7TvNpIAvOFS+4zTZbB8=";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkg-config autoreconfHook ];
|
|
buildInputs = [
|
|
zlib readline openssl libassuan
|
|
libXt libxslt libiconv docbook_xml_dtd_412
|
|
]
|
|
++ lib.optional stdenv.hostPlatform.isDarwin Carbon
|
|
++ (if withApplePCSC then [ PCSC ] else [ pcsclite ]);
|
|
|
|
env.NIX_CFLAGS_COMPILE = "-Wno-error";
|
|
|
|
configureFlags = [
|
|
"--enable-zlib"
|
|
"--enable-readline"
|
|
"--enable-openssl"
|
|
"--enable-pcsc"
|
|
"--enable-sm"
|
|
"--enable-man"
|
|
"--enable-doc"
|
|
"--localstatedir=/var"
|
|
"--sysconfdir=/etc"
|
|
"--with-xsl-stylesheetsdir=${docbook_xsl}/xml/xsl/docbook"
|
|
"--with-pcsc-provider=${
|
|
if withApplePCSC then
|
|
"${PCSC}/Library/Frameworks/PCSC.framework/PCSC"
|
|
else
|
|
"${lib.getLib pcsclite}/lib/libpcsclite${stdenv.hostPlatform.extensions.sharedLibrary}"
|
|
}"
|
|
(lib.optionalString (stdenv.hostPlatform != stdenv.buildPlatform)
|
|
"XSLTPROC=${buildPackages.libxslt}/bin/xsltproc")
|
|
];
|
|
|
|
PCSC_CFLAGS = lib.optionalString withApplePCSC
|
|
"-I${PCSC}/Library/Frameworks/PCSC.framework/Headers";
|
|
|
|
installFlags = [
|
|
"sysconfdir=$(out)/etc"
|
|
"completiondir=$(out)/etc"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Set of libraries and utilities to access smart cards";
|
|
homepage = "https://github.com/OpenSC/OpenSC/wiki";
|
|
license = licenses.lgpl21Plus;
|
|
platforms = platforms.all;
|
|
maintainers = [ maintainers.michaeladler ];
|
|
};
|
|
}
|