mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-04 04:46:43 +00:00
e0816431a2
Otherwise references to the Python interpreter inside the set are wrong, as demonstrated by:
``` nix
with import <nixpkgs> { };
let
python' = python3.override {
packageOverrides = final: prev: { requests = prev.requests.overridePythonAttrs(old: { version = "1337"; }); };
};
in python'.pkgs.python.pkgs.requests
```
which returns the _non_ overriden requests.
And the same with `self`:
```
with import <nixpkgs> { };
let
python' = python3.override {
self = python';
packageOverrides = final: prev: { requests = prev.requests.overridePythonAttrs(old: { version = "1337"; }); };
};
in python'.pkgs.python.pkgs.requests
```
which returns the overriden requests.
This can manifest itself as file collisions when constructing environments or as subtly incorrect dependency graphs.
117 lines
2.2 KiB
Nix
117 lines
2.2 KiB
Nix
{ lib
|
|
, fetchzip
|
|
, python310
|
|
, rtlcss
|
|
, wkhtmltopdf
|
|
, nixosTests
|
|
}:
|
|
|
|
let
|
|
python = python310.override {
|
|
self = python;
|
|
packageOverrides = self: super: {
|
|
flask = super.flask.overridePythonAttrs (old: rec {
|
|
version = "2.3.3";
|
|
src = old.src.override {
|
|
inherit version;
|
|
hash = "sha256-CcNHqSqn/0qOfzIGeV8w2CZlS684uHPQdEzVccpgnvw=";
|
|
};
|
|
});
|
|
werkzeug = super.werkzeug.overridePythonAttrs (old: rec {
|
|
version = "2.3.7";
|
|
src = old.src.override {
|
|
inherit version;
|
|
hash = "sha256-K4wORHtLnbzIXdl7butNy69si2w74L1lTiVVPgohV9g=";
|
|
};
|
|
disabledTests = old.disabledTests ++ [
|
|
"test_response_body"
|
|
];
|
|
});
|
|
};
|
|
};
|
|
|
|
odoo_version = "16.0";
|
|
odoo_release = "20231024";
|
|
in python.pkgs.buildPythonApplication rec {
|
|
pname = "odoo";
|
|
version = "${odoo_version}.${odoo_release}";
|
|
|
|
format = "setuptools";
|
|
|
|
# latest release is at https://github.com/odoo/docker/blob/master/16.0/Dockerfile
|
|
src = fetchzip {
|
|
url = "https://nightly.odoo.com/${odoo_version}/nightly/src/odoo_${version}.zip";
|
|
name = "${pname}-${version}";
|
|
hash = "sha256-Ux8RfA7kWLKissBBY5wrfL+aKKw++5BxjP3Vw0JAOsk="; # odoo
|
|
};
|
|
|
|
# needs some investigation
|
|
doCheck = false;
|
|
|
|
makeWrapperArgs = [
|
|
"--prefix" "PATH" ":" "${lib.makeBinPath [ wkhtmltopdf rtlcss ]}"
|
|
];
|
|
|
|
propagatedBuildInputs = with python.pkgs; [
|
|
babel
|
|
chardet
|
|
cryptography
|
|
decorator
|
|
docutils
|
|
ebaysdk
|
|
freezegun
|
|
gevent
|
|
greenlet
|
|
idna
|
|
jinja2
|
|
libsass
|
|
lxml
|
|
markupsafe
|
|
num2words
|
|
ofxparse
|
|
passlib
|
|
pillow
|
|
polib
|
|
psutil
|
|
psycopg2
|
|
pydot
|
|
pyopenssl
|
|
pypdf2
|
|
pyserial
|
|
python-dateutil
|
|
python-ldap
|
|
python-stdnum
|
|
pytz
|
|
pyusb
|
|
qrcode
|
|
reportlab
|
|
requests
|
|
urllib3
|
|
vobject
|
|
werkzeug
|
|
xlrd
|
|
xlsxwriter
|
|
xlwt
|
|
zeep
|
|
|
|
setuptools
|
|
mock
|
|
];
|
|
|
|
# takes 5+ minutes and there are not files to strip
|
|
dontStrip = true;
|
|
|
|
passthru = {
|
|
tests = {
|
|
inherit (nixosTests) odoo;
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Open Source ERP and CRM";
|
|
homepage = "https://www.odoo.com/";
|
|
license = licenses.lgpl3Only;
|
|
maintainers = with maintainers; [ mkg20001 ];
|
|
};
|
|
}
|