mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-28 01:43:15 +00:00
eb04659fc2
This was achieved using the following command:
sd 'wrapGAppsHook\b' wrapGAppsHook3 (rg -l 'wrapGAppsHook\b')
And then manually reverted the following changes:
- alias in top-level.nix
- function name in wrap-gapps-hook.sh
- comment in postFixup of at-spi2-core
- comment in gtk4
- comment in preFixup of 1password-gui/linux.nix
- comment in postFixup of qgis/unwrapped-ltr.nix and qgis/unwrapped.nix
- comment in postFixup of telegram-desktop
- comment in postFixup of fwupd
- buildCommand of mongodb-compass
- postFixup of xflux-gui
- comment in a patch in kdePackages.kde-gtk-config and plasma5Packages.kde-gtk-config
- description of programs.sway.wrapperFeatures.gtk NixOS option (manual rebuild)
82 lines
1.7 KiB
Nix
82 lines
1.7 KiB
Nix
{ lib
|
|
, fetchurl
|
|
, gdk-pixbuf
|
|
, gobject-introspection
|
|
, gtk3
|
|
, mcomix
|
|
, python3
|
|
, testers
|
|
, wrapGAppsHook3
|
|
|
|
# Recommended Dependencies:
|
|
, p7zip
|
|
, unrar
|
|
, chardetSupport ? true
|
|
, pdfSupport ? true
|
|
, unrarSupport ? false # unfree software
|
|
}:
|
|
|
|
python3.pkgs.buildPythonApplication rec {
|
|
pname = "mcomix";
|
|
version = "3.1.0";
|
|
pyproject = true;
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/mcomix/mcomix-${version}.tar.gz";
|
|
hash = "sha256-+Shuun/7w86VKBNamTmCPEJfO76fdKY5+HBvzCi0xCc=";
|
|
};
|
|
|
|
buildInputs = [
|
|
gtk3
|
|
gdk-pixbuf
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
gobject-introspection
|
|
python3.pkgs.setuptools
|
|
wrapGAppsHook3
|
|
];
|
|
|
|
propagatedBuildInputs = with python3.pkgs; [
|
|
pillow
|
|
pycairo
|
|
pygobject3
|
|
]
|
|
++ lib.optionals chardetSupport [ chardet ]
|
|
++ lib.optionals pdfSupport [ pymupdf ];
|
|
|
|
# No tests included in .tar.gz
|
|
doCheck = false;
|
|
|
|
# Prevent double wrapping
|
|
dontWrapGApps = true;
|
|
|
|
preFixup = ''
|
|
makeWrapperArgs+=(
|
|
"''${gappsWrapperArgs[@]}"
|
|
"--prefix" "PATH" ":" "${lib.makeBinPath ([ p7zip ] ++ lib.optional unrarSupport unrar)}"
|
|
)
|
|
'';
|
|
|
|
postInstall = ''
|
|
cp -a share $out/
|
|
'';
|
|
|
|
passthru.tests.version = testers.testVersion {
|
|
package = mcomix;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Comic book reader and image viewer";
|
|
mainProgram = "mcomix";
|
|
longDescription = ''
|
|
User-friendly, customizable image viewer, specifically designed to handle
|
|
comic books and manga supporting a variety of container formats
|
|
(including CBR, CBZ, CB7, CBT, LHA and PDF)
|
|
'';
|
|
homepage = "https://sourceforge.net/projects/mcomix/";
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ thiagokokada ];
|
|
};
|
|
}
|