mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-20 12:43:52 +00:00
4f0dadbf38
After final improvements to the official formatter implementation, this commit now performs the first treewide reformat of Nix files using it. This is part of the implementation of RFC 166. Only "inactive" files are reformatted, meaning only files that aren't being touched by any PR with activity in the past 2 months. This is to avoid conflicts for PRs that might soon be merged. Later we can do a full treewide reformat to get the rest, which should not cause as many conflicts. A CI check has already been running for some time to ensure that new and already-formatted files are formatted, so the files being reformatted here should also stay formatted. This commit was automatically created and can be verified using nix-builda08b3a4d19
.tar.gz \ --argstr baseRevb32a094368
result/bin/apply-formatting $NIXPKGS_PATH
110 lines
3.1 KiB
Nix
110 lines
3.1 KiB
Nix
# Test Traefik as a reverse proxy of a local web service
|
|
# and a Docker container.
|
|
import ./make-test-python.nix (
|
|
{ pkgs, ... }:
|
|
{
|
|
name = "traefik";
|
|
meta = with pkgs.lib.maintainers; {
|
|
maintainers = [ joko ];
|
|
};
|
|
|
|
nodes = {
|
|
client =
|
|
{ config, pkgs, ... }:
|
|
{
|
|
environment.systemPackages = [ pkgs.curl ];
|
|
};
|
|
traefik =
|
|
{ config, pkgs, ... }:
|
|
{
|
|
virtualisation.oci-containers = {
|
|
backend = "docker";
|
|
containers.nginx = {
|
|
extraOptions = [
|
|
"-l"
|
|
"traefik.enable=true"
|
|
"-l"
|
|
"traefik.http.routers.nginx.entrypoints=web"
|
|
"-l"
|
|
"traefik.http.routers.nginx.rule=Host(`nginx.traefik.test`)"
|
|
];
|
|
image = "nginx-container";
|
|
imageStream = pkgs.dockerTools.examples.nginxStream;
|
|
};
|
|
};
|
|
|
|
networking.firewall.allowedTCPPorts = [ 80 ];
|
|
|
|
services.traefik = {
|
|
enable = true;
|
|
|
|
dynamicConfigOptions = {
|
|
http.routers.simplehttp = {
|
|
rule = "Host(`simplehttp.traefik.test`)";
|
|
entryPoints = [ "web" ];
|
|
service = "simplehttp";
|
|
};
|
|
|
|
http.services.simplehttp = {
|
|
loadBalancer.servers = [
|
|
{
|
|
url = "http://127.0.0.1:8000";
|
|
}
|
|
];
|
|
};
|
|
};
|
|
|
|
staticConfigOptions = {
|
|
global = {
|
|
checkNewVersion = false;
|
|
sendAnonymousUsage = false;
|
|
};
|
|
|
|
entryPoints.web.address = ":\${HTTP_PORT}";
|
|
|
|
providers.docker.exposedByDefault = false;
|
|
};
|
|
environmentFiles = [
|
|
(pkgs.writeText "traefik.env" ''
|
|
HTTP_PORT=80
|
|
'')
|
|
];
|
|
};
|
|
|
|
systemd.services.simplehttp = {
|
|
script = "${pkgs.python3}/bin/python -m http.server 8000";
|
|
serviceConfig.Type = "simple";
|
|
wantedBy = [ "multi-user.target" ];
|
|
};
|
|
|
|
users.users.traefik.extraGroups = [ "docker" ];
|
|
};
|
|
};
|
|
|
|
testScript = ''
|
|
start_all()
|
|
|
|
traefik.wait_for_unit("docker-nginx.service")
|
|
traefik.wait_until_succeeds("docker ps | grep nginx-container")
|
|
traefik.wait_for_unit("simplehttp.service")
|
|
traefik.wait_for_unit("traefik.service")
|
|
traefik.wait_for_open_port(80)
|
|
traefik.wait_for_unit("multi-user.target")
|
|
|
|
client.wait_for_unit("multi-user.target")
|
|
|
|
client.wait_until_succeeds("curl -sSf -H Host:nginx.traefik.test http://traefik/")
|
|
|
|
with subtest("Check that a container can be reached via Traefik"):
|
|
assert "Hello from NGINX" in client.succeed(
|
|
"curl -sSf -H Host:nginx.traefik.test http://traefik/"
|
|
)
|
|
|
|
with subtest("Check that dynamic configuration works"):
|
|
assert "Directory listing for " in client.succeed(
|
|
"curl -sSf -H Host:simplehttp.traefik.test http://traefik/"
|
|
)
|
|
'';
|
|
}
|
|
)
|