mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-29 10:23:29 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
63 lines
1.9 KiB
Nix
63 lines
1.9 KiB
Nix
{ version, sha256, platforms, patches ? [ ] }:
|
|
|
|
{ lib, stdenv, fetchFromGitHub
|
|
, meson, pkg-config, ninja, docutils, makeWrapper
|
|
, fuse3, macfuse-stubs, glib
|
|
, which, python3Packages
|
|
, openssh
|
|
}:
|
|
|
|
let
|
|
fuse = if stdenv.hostPlatform.isDarwin then macfuse-stubs else fuse3;
|
|
in stdenv.mkDerivation rec {
|
|
pname = "sshfs-fuse";
|
|
inherit version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "libfuse";
|
|
repo = "sshfs";
|
|
rev = "sshfs-${version}";
|
|
inherit sha256;
|
|
};
|
|
|
|
inherit patches;
|
|
|
|
nativeBuildInputs = [ meson pkg-config ninja docutils makeWrapper ];
|
|
buildInputs = [ fuse glib ];
|
|
nativeCheckInputs = [ which python3Packages.pytest ];
|
|
|
|
env.NIX_CFLAGS_COMPILE = lib.optionalString
|
|
(stdenv.hostPlatform.system == "i686-linux")
|
|
"-D_FILE_OFFSET_BITS=64";
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/sbin
|
|
ln -sf $out/bin/sshfs $out/sbin/mount.sshfs
|
|
'' + lib.optionalString (!stdenv.hostPlatform.isDarwin) ''
|
|
wrapProgram $out/bin/sshfs --prefix PATH : "${openssh}/bin"
|
|
'';
|
|
|
|
# doCheck = true;
|
|
checkPhase = lib.optionalString (!stdenv.hostPlatform.isDarwin) ''
|
|
# The tests need fusermount:
|
|
mkdir bin
|
|
cp ${fuse}/bin/fusermount3 bin/fusermount
|
|
export PATH=bin:$PATH
|
|
# Can't access /dev/fuse within the sandbox: "FUSE kernel module does not seem to be loaded"
|
|
substituteInPlace test/util.py --replace "/dev/fuse" "/dev/null"
|
|
# TODO: "fusermount executable not setuid, and we are not root"
|
|
# We should probably use a VM test instead
|
|
${python3Packages.python.interpreter} -m pytest test/
|
|
'';
|
|
|
|
meta = with lib; {
|
|
inherit platforms;
|
|
description = "FUSE-based filesystem that allows remote filesystems to be mounted over SSH";
|
|
longDescription = macfuse-stubs.warning;
|
|
homepage = "https://github.com/libfuse/sshfs";
|
|
license = licenses.gpl2Plus;
|
|
mainProgram = "sshfs";
|
|
maintainers = with maintainers; [ primeos ];
|
|
};
|
|
}
|