mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-02 03:43:06 +00:00
63 lines
1.7 KiB
Nix
63 lines
1.7 KiB
Nix
# This function downloads and unpacks an archive file, such as a zip
|
|
# or tar file. This is primarily useful for dynamically generated
|
|
# archives, such as GitHub's /archive URLs, where the unpacked content
|
|
# of the zip file doesn't change, but the zip file itself may
|
|
# (e.g. due to minor changes in the compression algorithm, or changes
|
|
# in timestamps).
|
|
|
|
{ lib, fetchurl, unzip }:
|
|
|
|
{ # Optionally move the contents of the unpacked tree up one level.
|
|
stripRoot ? true
|
|
, url ? ""
|
|
, urls ? []
|
|
, extraPostFetch ? ""
|
|
, name ? "source"
|
|
, ... } @ args:
|
|
|
|
(fetchurl (let
|
|
basename = baseNameOf (if url != "" then url else builtins.head urls);
|
|
in {
|
|
inherit name;
|
|
|
|
recursiveHash = true;
|
|
|
|
downloadToTemp = true;
|
|
|
|
postFetch =
|
|
''
|
|
unpackDir="$TMPDIR/unpack"
|
|
mkdir "$unpackDir"
|
|
cd "$unpackDir"
|
|
|
|
renamed="$TMPDIR/${basename}"
|
|
mv "$downloadedFile" "$renamed"
|
|
unpackFile "$renamed"
|
|
''
|
|
+ (if stripRoot then ''
|
|
if [ $(ls "$unpackDir" | wc -l) != 1 ]; then
|
|
echo "error: zip file must contain a single file or directory."
|
|
echo "hint: Pass stripRoot=false; to fetchzip to assume flat list of files."
|
|
exit 1
|
|
fi
|
|
fn=$(cd "$unpackDir" && echo *)
|
|
if [ -f "$unpackDir/$fn" ]; then
|
|
mkdir $out
|
|
fi
|
|
mv "$unpackDir/$fn" "$out"
|
|
'' else ''
|
|
mv "$unpackDir" "$out"
|
|
'')
|
|
+ ''
|
|
${extraPostFetch}
|
|
''
|
|
# Remove non-owner write permissions
|
|
# Fixes https://github.com/NixOS/nixpkgs/issues/38649
|
|
+ ''
|
|
chmod 755 "$out"
|
|
'';
|
|
} // removeAttrs args [ "stripRoot" "extraPostFetch" ])).overrideAttrs (x: {
|
|
# Hackety-hack: we actually need unzip hooks, too
|
|
nativeBuildInputs = x.nativeBuildInputs ++ [ unzip ];
|
|
})
|