mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 16:43:58 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
85 lines
2.4 KiB
Nix
85 lines
2.4 KiB
Nix
{
|
|
stdenv,
|
|
lib,
|
|
fetchurl,
|
|
perl,
|
|
gmp,
|
|
gf2x ? null,
|
|
# I asked the ntl maintainer weather or not to include gf2x by default:
|
|
# > If I remember correctly, gf2x is now thread safe, so there's no reason not to use it.
|
|
withGf2x ? true,
|
|
tune ? false, # tune for current system; non reproducible and time consuming
|
|
}:
|
|
|
|
assert withGf2x -> gf2x != null;
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "ntl";
|
|
version = "11.5.1";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.shoup.net/ntl/ntl-${version}.tar.gz";
|
|
sha256 = "sha256-IQ0GwxMGy8bq9oFEU8Vsd22djo3zbXTrMG9qUj0caoo=";
|
|
};
|
|
|
|
buildInputs = [
|
|
gmp
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
perl # needed for ./configure
|
|
];
|
|
|
|
sourceRoot = "${pname}-${version}/src";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
dontAddPrefix = true; # DEF_PREFIX instead
|
|
|
|
# Written in perl, does not support autoconf-style
|
|
# --build=/--host= options:
|
|
# Error: unrecognized option: --build=x86_64-unknown-linux-gnu
|
|
configurePlatforms = [ ];
|
|
|
|
# reference: http://shoup.net/ntl/doc/tour-unix.html
|
|
configureFlags =
|
|
[
|
|
"DEF_PREFIX=$(out)"
|
|
"SHARED=on" # genereate a shared library (as well as static)
|
|
"NATIVE=off" # don't target code to current hardware (reproducibility, portability)
|
|
"TUNE=${
|
|
if tune then
|
|
"auto"
|
|
else if stdenv.hostPlatform.isx86 then
|
|
"x86" # "chooses options that should be well suited for most x86 platforms"
|
|
else
|
|
"generic" # "chooses options that should be OK for most platforms"
|
|
}"
|
|
"CXX=${stdenv.cc.targetPrefix}c++"
|
|
]
|
|
++ lib.optionals withGf2x [
|
|
"NTL_GF2X_LIB=on"
|
|
"GF2X_PREFIX=${gf2x}"
|
|
];
|
|
|
|
doCheck = true; # takes some time
|
|
|
|
meta = with lib; {
|
|
description = "Library for doing Number Theory";
|
|
longDescription = ''
|
|
NTL is a high-performance, portable C++ library providing data
|
|
structures and algorithms for manipulating signed, arbitrary
|
|
length integers, and for vectors, matrices, and polynomials over
|
|
the integers and over finite fields.
|
|
'';
|
|
# Upstream contact: maintainer is victorshoup on GitHub. Alternatively the
|
|
# email listed on the homepage.
|
|
homepage = "http://www.shoup.net/ntl/";
|
|
# also locally at "${src}/doc/tour-changes.html";
|
|
changelog = "https://www.shoup.net/ntl/doc/tour-changes.html";
|
|
maintainers = teams.sage.members;
|
|
license = licenses.gpl2Plus;
|
|
platforms = platforms.all;
|
|
};
|
|
}
|