mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-29 16:24:10 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
92 lines
2.2 KiB
Nix
92 lines
2.2 KiB
Nix
{
|
||
lib,
|
||
stdenv,
|
||
fetchFromGitHub,
|
||
pkg-config,
|
||
python3,
|
||
meson,
|
||
ninja,
|
||
vala,
|
||
gtk3,
|
||
glib,
|
||
pantheon,
|
||
gtksourceview,
|
||
libgee,
|
||
nix-update-script,
|
||
webkitgtk_4_0,
|
||
libqalculate,
|
||
intltool,
|
||
gnuplot,
|
||
wrapGAppsHook3,
|
||
}:
|
||
|
||
stdenv.mkDerivation rec {
|
||
pname = "nasc";
|
||
version = "0.8.0";
|
||
|
||
src = fetchFromGitHub {
|
||
owner = "parnold-x";
|
||
repo = pname;
|
||
rev = version;
|
||
sha256 = "02b9a59a9fzsb6nn3ycwwbcbv04qfzm6x7csq2addpzx5wak6dd8";
|
||
fetchSubmodules = true;
|
||
};
|
||
|
||
nativeBuildInputs = [
|
||
glib # post_install.py
|
||
gtk3 # post_install.py
|
||
intltool # for libqalculate
|
||
meson
|
||
ninja
|
||
pkg-config
|
||
python3
|
||
vala
|
||
wrapGAppsHook3
|
||
];
|
||
|
||
buildInputs =
|
||
[
|
||
glib
|
||
gtk3
|
||
gtksourceview
|
||
libgee
|
||
pantheon.granite
|
||
webkitgtk_4_0
|
||
# We add libqalculate's runtime dependencies because nasc has it as a modified subproject.
|
||
]
|
||
++ libqalculate.buildInputs
|
||
++ libqalculate.propagatedBuildInputs;
|
||
|
||
postPatch = ''
|
||
chmod +x meson/post_install.py
|
||
patchShebangs meson/post_install.py
|
||
|
||
# patch subproject. same code in libqalculate expression
|
||
substituteInPlace subprojects/libqalculate/libqalculate/Calculator-plot.cc \
|
||
--replace 'commandline = "gnuplot"' 'commandline = "${gnuplot}/bin/gnuplot"' \
|
||
--replace '"gnuplot - ' '"${gnuplot}/bin/gnuplot - '
|
||
substituteInPlace subprojects/libqalculate/libqalculate/meson.build \
|
||
--replace "link_with: 'libqalculate_lib_static'" "link_with: libqalculate_lib_static"
|
||
'';
|
||
|
||
passthru = {
|
||
updateScript = nix-update-script { };
|
||
};
|
||
|
||
meta = with lib; {
|
||
description = "Do maths like a normal person, designed for elementary OS";
|
||
longDescription = ''
|
||
It’s an app where you do maths like a normal person. It lets you
|
||
type whatever you want and smartly figures out what is math and
|
||
spits out an answer on the right pane. Then you can plug those
|
||
answers in to future equations and if that answer changes, so does
|
||
the equations it’s used in.
|
||
'';
|
||
homepage = "https://github.com/parnold-x/nasc";
|
||
maintainers = teams.pantheon.members;
|
||
platforms = platforms.linux;
|
||
license = licenses.gpl3Plus;
|
||
mainProgram = "com.github.parnold_x.nasc";
|
||
};
|
||
}
|