mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-02 19:14:14 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
92 lines
2.2 KiB
Nix
92 lines
2.2 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, rustPlatform
|
|
, darwin
|
|
, pandoc
|
|
, pkg-config
|
|
, openssl
|
|
, installShellFiles
|
|
, copyDesktopItems
|
|
, makeDesktopItem
|
|
, nix-update-script
|
|
, testers
|
|
, writeText
|
|
, runCommand
|
|
, fend
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "fend";
|
|
version = "1.5.3";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "printfn";
|
|
repo = "fend";
|
|
rev = "v${version}";
|
|
hash = "sha256-mokBvBJlqvrherpZ+qMy86CXESXlaC6Qh3LISmmfR0Q=";
|
|
};
|
|
|
|
cargoHash = "sha256-+8rXZ+xX2fqm0+tFnyQK9HXa/ZuIcbvtzVrB5cOUCp4=";
|
|
|
|
nativeBuildInputs = [ pandoc installShellFiles pkg-config copyDesktopItems ];
|
|
buildInputs = [ pkg-config openssl ] ++ lib.optionals stdenv.hostPlatform.isDarwin [ darwin.apple_sdk.frameworks.Security ];
|
|
|
|
postBuild = ''
|
|
patchShebangs --build ./documentation/build.sh
|
|
./documentation/build.sh
|
|
'';
|
|
|
|
preFixup = ''
|
|
installManPage documentation/fend.1
|
|
'';
|
|
|
|
doInstallCheck = true;
|
|
|
|
installCheckPhase = ''
|
|
[[ "$($out/bin/fend "1 km to m")" = "1000 m" ]]
|
|
'';
|
|
|
|
postInstall = ''
|
|
install -D -m 444 $src/icon/icon.svg $out/share/icons/hicolor/scalable/apps/fend.svg
|
|
'';
|
|
|
|
desktopItems = [
|
|
(makeDesktopItem {
|
|
name = "fend";
|
|
desktopName = "fend";
|
|
genericName = "Calculator";
|
|
comment = "Arbitrary-precision unit-aware calculator";
|
|
icon = "fend";
|
|
exec = "fend";
|
|
terminal = true;
|
|
categories = [ "Utility" "Calculator" "ConsoleOnly" ];
|
|
})
|
|
];
|
|
|
|
passthru = {
|
|
updateScript = nix-update-script { };
|
|
tests = {
|
|
version = testers.testVersion { package = fend; };
|
|
units = testers.testEqualContents {
|
|
assertion = "fend does simple math and unit conversions";
|
|
expected = writeText "expected" ''
|
|
36 kph
|
|
'';
|
|
actual = runCommand "actual" { } ''
|
|
${lib.getExe fend} '(100 meters) / (10 seconds) to kph' > $out
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Arbitrary-precision unit-aware calculator";
|
|
homepage = "https://github.com/printfn/fend";
|
|
changelog = "https://github.com/printfn/fend/releases/tag/v${version}";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ djanatyn liff ];
|
|
mainProgram = "fend";
|
|
};
|
|
}
|