mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-17 18:34:38 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
40 lines
1.3 KiB
Nix
40 lines
1.3 KiB
Nix
{ lib, stdenv, fetchurl, dovecot, openssl }:
|
|
let
|
|
dovecotMajorMinor = lib.versions.majorMinor dovecot.version;
|
|
in stdenv.mkDerivation rec {
|
|
pname = "dovecot-pigeonhole";
|
|
version = "0.5.21.1";
|
|
|
|
src = fetchurl {
|
|
url = "https://pigeonhole.dovecot.org/releases/${dovecotMajorMinor}/dovecot-${dovecotMajorMinor}-pigeonhole-${version}.tar.gz";
|
|
hash = "sha256-A3fbKEtiByPeBgQxEV+y53keHfQyFBGvcYIB1pJcRpI=";
|
|
};
|
|
|
|
buildInputs = [ dovecot openssl ];
|
|
|
|
preConfigure = ''
|
|
substituteInPlace src/managesieve/managesieve-settings.c --replace \
|
|
".executable = \"managesieve\"" \
|
|
".executable = \"$out/libexec/dovecot/managesieve\""
|
|
substituteInPlace src/managesieve-login/managesieve-login-settings.c --replace \
|
|
".executable = \"managesieve-login\"" \
|
|
".executable = \"$out/libexec/dovecot/managesieve-login\""
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--with-dovecot=${dovecot}/lib/dovecot"
|
|
"--without-dovecot-install-dirs"
|
|
"--with-moduledir=$(out)/lib/dovecot"
|
|
];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with lib; {
|
|
homepage = "https://pigeonhole.dovecot.org/";
|
|
description = "Sieve plugin for the Dovecot IMAP server";
|
|
license = licenses.lgpl21Only;
|
|
maintainers = with maintainers; [ globin ] ++ teams.helsinki-systems.members;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|