mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-24 14:43:37 +00:00
9bb3fccb5b
continuation of #109595 pkgconfig was aliased in 2018, however, it remained in all-packages.nix due to its wide usage. This cleans up the remaining references to pkgs.pkgsconfig and moves the entry to aliases.nix. python3Packages.pkgconfig remained unchanged because it's the canonical name of the upstream package on pypi.
56 lines
1.7 KiB
Nix
56 lines
1.7 KiB
Nix
{ stdenv, lib, fetchurl, autoconf, automake, pkg-config, libtool
|
|
, gtk2, halibut, ncurses, perl, darwin
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "0.74";
|
|
pname = "putty";
|
|
|
|
src = fetchurl {
|
|
urls = [
|
|
"https://the.earth.li/~sgtatham/putty/${version}/${pname}-${version}.tar.gz"
|
|
"ftp://ftp.wayne.edu/putty/putty-website-mirror/${version}/${pname}-${version}.tar.gz"
|
|
];
|
|
sha256 = "0zc43g8ycyf712cdrja4k8ih5s3agw1k0nq0jkifdn8xwn4d7mfx";
|
|
};
|
|
|
|
# glib-2.62 deprecations
|
|
NIX_CFLAGS_COMPILE = "-DGLIB_DISABLE_DEPRECATION_WARNINGS";
|
|
|
|
preConfigure = lib.optionalString stdenv.hostPlatform.isUnix ''
|
|
perl mkfiles.pl
|
|
( cd doc ; make );
|
|
./mkauto.sh
|
|
cd unix
|
|
'' + lib.optionalString stdenv.hostPlatform.isWindows ''
|
|
cd windows
|
|
'';
|
|
|
|
TOOLPATH = stdenv.cc.targetPrefix;
|
|
makefile = if stdenv.hostPlatform.isWindows then "Makefile.mgw" else null;
|
|
|
|
installPhase = if stdenv.hostPlatform.isWindows then ''
|
|
for exe in *.exe; do
|
|
install -D $exe $out/bin/$exe
|
|
done
|
|
'' else null;
|
|
|
|
nativeBuildInputs = [ autoconf automake halibut libtool perl pkg-config ];
|
|
buildInputs = lib.optionals stdenv.hostPlatform.isUnix [
|
|
gtk2 ncurses
|
|
] ++ lib.optional stdenv.isDarwin darwin.apple_sdk.libs.utmp;
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with lib; {
|
|
description = "A Free Telnet/SSH Client";
|
|
longDescription = ''
|
|
PuTTY is a free implementation of Telnet and SSH for Windows and Unix
|
|
platforms, along with an xterm terminal emulator.
|
|
It is written and maintained primarily by Simon Tatham.
|
|
'';
|
|
homepage = "https://www.chiark.greenend.org.uk/~sgtatham/putty/";
|
|
license = licenses.mit;
|
|
platforms = platforms.unix ++ platforms.windows;
|
|
};
|
|
}
|