mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-12 00:33:10 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
53 lines
1.6 KiB
Nix
53 lines
1.6 KiB
Nix
{ lib, stdenv, fetchFromGitLab }:
|
|
|
|
let
|
|
# These settings are found in the Makefile, but there seems to be no
|
|
# way to select one or the other setting other than editing the file
|
|
# manually, so we have to duplicate the know how here.
|
|
systemFlags = lib.optionalString stdenv.hostPlatform.isDarwin ''
|
|
CFLAGS="-O2 -Wall -fomit-frame-pointer -no-cpp-precomp"
|
|
LDFLAGS=
|
|
'' + lib.optionalString stdenv.hostPlatform.isCygwin ''
|
|
CFLAGS="-O2 -Wall -fomit-frame-pointer"
|
|
LDFLAGS=-s
|
|
TREE_DEST=tree.exe
|
|
'' + lib.optionalString (stdenv.hostPlatform.isFreeBSD || stdenv.hostPlatform.isOpenBSD) ''
|
|
CFLAGS="-O2 -Wall -fomit-frame-pointer"
|
|
LDFLAGS=-s
|
|
''; # use linux flags by default
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "tree";
|
|
version = "2.1.3";
|
|
|
|
src = fetchFromGitLab {
|
|
owner = "OldManProgrammer";
|
|
repo = "unix-tree";
|
|
rev = version;
|
|
hash = "sha256-Adc/BLKIzwjJztNxF4scmnsufoc/++x1F1IaobMn1rc=";
|
|
};
|
|
|
|
preConfigure = ''
|
|
makeFlagsArray+=(${systemFlags})
|
|
'';
|
|
|
|
makeFlags = [
|
|
"CC=${stdenv.cc.targetPrefix}cc"
|
|
"PREFIX=${placeholder "out"}"
|
|
];
|
|
|
|
meta = with lib; {
|
|
homepage = "https://oldmanprogrammer.net/source.php?dir=projects/tree";
|
|
description = "Command to produce a depth indented directory listing";
|
|
license = licenses.gpl2Plus;
|
|
longDescription = ''
|
|
Tree is a recursive directory listing command that produces a
|
|
depth indented listing of files, which is colorized ala dircolors if
|
|
the LS_COLORS environment variable is set and output is to tty.
|
|
'';
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; [ nickcao ];
|
|
mainProgram = "tree";
|
|
};
|
|
}
|