mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-31 18:15:54 +00:00
6149d31915
This allows the cross compilation of chicken in, at least, the following ways: ```sh nix-build -A pkgsCross.aarch64-multiplatform.chicken ``` and ```sh nix-build -A pkgsCross.raspberryPi.chicken ``` Building with clang on x86_64-linux has also been repaired. Additionally, instead of reimplementing a version tester in the `installCheckPhase`, this test has been pulled out into its own tester attribute. While two broken tests needed to be disabled, the functionality of static building is not broken. Only the tests themselves seem not to be able to handle the specification of absolute compiler paths.
84 lines
2.7 KiB
Nix
84 lines
2.7 KiB
Nix
{ lib, stdenv, fetchurl, makeWrapper, darwin, bootstrap-chicken ? null, testers }:
|
|
|
|
let
|
|
platform = with stdenv;
|
|
if isDarwin then "macosx"
|
|
else if isCygwin then "cygwin"
|
|
else if (isFreeBSD || isOpenBSD) then "bsd"
|
|
else if isSunOS then "solaris"
|
|
else "linux"; # Should be a sane default
|
|
in
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "chicken";
|
|
version = "5.3.0";
|
|
|
|
binaryVersion = 11;
|
|
|
|
src = fetchurl {
|
|
url = "https://code.call-cc.org/releases/${finalAttrs.version}/chicken-${finalAttrs.version}.tar.gz";
|
|
sha256 = "sha256-w62Z2PnhftgQkS75gaw7DC4vRvsOzAM7XDttyhvbDXY=";
|
|
};
|
|
|
|
# Disable two broken tests: "static link" and "linking tests"
|
|
postPatch = ''
|
|
sed -i tests/runtests.sh -e "/static link/,+4 { s/^/# / }"
|
|
sed -i tests/runtests.sh -e "/linking tests/,+11 { s/^/# / }"
|
|
'';
|
|
|
|
setupHook = lib.optional (bootstrap-chicken != null) ./setup-hook.sh;
|
|
|
|
# -fno-strict-overflow is not a supported argument in clang
|
|
hardeningDisable = lib.optionals stdenv.cc.isClang [ "strictoverflow" ];
|
|
|
|
makeFlags = [
|
|
"PLATFORM=${platform}"
|
|
"PREFIX=$(out)"
|
|
"C_COMPILER=$(CC)"
|
|
"CXX_COMPILER=$(CXX)"
|
|
"TARGET_C_COMPILER=${stdenv.cc}/bin/${stdenv.cc.targetPrefix}cc"
|
|
"TARGET_CXX_COMPILER=${stdenv.cc}/bin/${stdenv.cc.targetPrefix}c++"
|
|
] ++ (lib.optionals stdenv.isDarwin [
|
|
"XCODE_TOOL_PATH=${darwin.binutils.bintools}/bin"
|
|
"LINKER_OPTIONS=-headerpad_max_install_names"
|
|
"POSTINSTALL_PROGRAM=install_name_tool"
|
|
]) ++ (lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
|
|
"HOSTSYSTEM=${stdenv.hostPlatform.config}"
|
|
]);
|
|
|
|
nativeBuildInputs = [
|
|
makeWrapper
|
|
] ++ lib.optionals (stdenv.isDarwin && stdenv.isAarch64) [
|
|
darwin.autoSignDarwinBinariesHook
|
|
];
|
|
|
|
buildInputs = lib.optionals (bootstrap-chicken != null) [
|
|
bootstrap-chicken
|
|
];
|
|
|
|
doCheck = !stdenv.isDarwin;
|
|
postCheck = ''
|
|
./csi -R chicken.pathname -R chicken.platform \
|
|
-p "(assert (equal? \"${toString finalAttrs.binaryVersion}\" (pathname-file (car (repository-path)))))"
|
|
'';
|
|
|
|
passthru.tests.version = testers.testVersion {
|
|
package = finalAttrs.finalPackage;
|
|
command = "csi -version";
|
|
};
|
|
|
|
meta = {
|
|
homepage = "https://call-cc.org/";
|
|
license = lib.licenses.bsd3;
|
|
maintainers = with lib.maintainers; [ corngood nagy konst-aa ];
|
|
platforms = lib.platforms.unix;
|
|
description = "A portable compiler for the Scheme programming language";
|
|
longDescription = ''
|
|
CHICKEN is a compiler for the Scheme programming language.
|
|
CHICKEN produces portable and efficient C, supports almost all
|
|
of the R5RS Scheme language standard, and includes many
|
|
enhancements and extensions. CHICKEN runs on Linux, macOS,
|
|
Windows, and many Unix flavours.
|
|
'';
|
|
};
|
|
})
|