mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-29 00:04:14 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
96 lines
2.3 KiB
Nix
96 lines
2.3 KiB
Nix
import ../make-test-python.nix (
|
|
{
|
|
pkgs,
|
|
lib,
|
|
kernelPackages ? null,
|
|
...
|
|
}:
|
|
let
|
|
wg-snakeoil-keys = import ./snakeoil-keys.nix;
|
|
peer = (import ./make-peer.nix) { inherit lib; };
|
|
in
|
|
{
|
|
name = "wireguard";
|
|
meta = with pkgs.lib.maintainers; {
|
|
maintainers = [ ma27 ];
|
|
};
|
|
|
|
nodes = {
|
|
peer0 = peer {
|
|
ip4 = "192.168.0.1";
|
|
ip6 = "fd00::1";
|
|
extraConfig = {
|
|
boot = lib.mkIf (kernelPackages != null) { inherit kernelPackages; };
|
|
networking.firewall.allowedUDPPorts = [ 23542 ];
|
|
networking.wireguard.interfaces.wg0 = {
|
|
ips = [
|
|
"10.23.42.1/32"
|
|
"fc00::1/128"
|
|
];
|
|
listenPort = 23542;
|
|
|
|
inherit (wg-snakeoil-keys.peer0) privateKey;
|
|
|
|
peers = lib.singleton {
|
|
allowedIPs = [
|
|
"10.23.42.2/32"
|
|
"fc00::2/128"
|
|
];
|
|
|
|
inherit (wg-snakeoil-keys.peer1) publicKey;
|
|
};
|
|
};
|
|
};
|
|
};
|
|
|
|
peer1 = peer {
|
|
ip4 = "192.168.0.2";
|
|
ip6 = "fd00::2";
|
|
extraConfig = {
|
|
boot = lib.mkIf (kernelPackages != null) { inherit kernelPackages; };
|
|
networking.wireguard.interfaces.wg0 = {
|
|
ips = [
|
|
"10.23.42.2/32"
|
|
"fc00::2/128"
|
|
];
|
|
listenPort = 23542;
|
|
allowedIPsAsRoutes = false;
|
|
|
|
inherit (wg-snakeoil-keys.peer1) privateKey;
|
|
|
|
peers = lib.singleton {
|
|
allowedIPs = [
|
|
"0.0.0.0/0"
|
|
"::/0"
|
|
];
|
|
endpoint = "192.168.0.1:23542";
|
|
persistentKeepalive = 25;
|
|
|
|
inherit (wg-snakeoil-keys.peer0) publicKey;
|
|
};
|
|
|
|
postSetup =
|
|
let
|
|
inherit (pkgs) iproute2;
|
|
in
|
|
''
|
|
${iproute2}/bin/ip route replace 10.23.42.1/32 dev wg0
|
|
${iproute2}/bin/ip route replace fc00::1/128 dev wg0
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
};
|
|
|
|
testScript = ''
|
|
start_all()
|
|
|
|
peer0.wait_for_unit("wireguard-wg0.service")
|
|
peer1.wait_for_unit("wireguard-wg0.service")
|
|
|
|
peer1.succeed("ping -c5 fc00::1")
|
|
peer1.succeed("ping -c5 10.23.42.1")
|
|
'';
|
|
}
|
|
)
|