mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-26 23:54:01 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
67 lines
1.9 KiB
Nix
67 lines
1.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
let
|
|
cfg = config.services.mame;
|
|
mame = "mame${lib.optionalString pkgs.stdenv.hostPlatform.is64bit "64"}";
|
|
in
|
|
{
|
|
options = {
|
|
services.mame = {
|
|
enable = lib.mkOption {
|
|
type = lib.types.bool;
|
|
default = false;
|
|
description = ''
|
|
Whether to setup TUN/TAP Ethernet interface for MAME emulator.
|
|
'';
|
|
};
|
|
user = lib.mkOption {
|
|
type = lib.types.str;
|
|
description = ''
|
|
User from which you run MAME binary.
|
|
'';
|
|
};
|
|
hostAddr = lib.mkOption {
|
|
type = lib.types.str;
|
|
description = ''
|
|
IP address of the host system. Usually an address of the main network
|
|
adapter or the adapter through which you get an internet connection.
|
|
'';
|
|
example = "192.168.31.156";
|
|
};
|
|
emuAddr = lib.mkOption {
|
|
type = lib.types.str;
|
|
description = ''
|
|
IP address of the guest system. The same you set inside guest OS under
|
|
MAME. Should be on the same subnet as {option}`services.mame.hostAddr`.
|
|
'';
|
|
example = "192.168.31.155";
|
|
};
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
environment.systemPackages = [ pkgs.mame ];
|
|
|
|
security.wrappers."${mame}" = {
|
|
owner = "root";
|
|
group = "root";
|
|
capabilities = "cap_net_admin,cap_net_raw+eip";
|
|
source = "${pkgs.mame}/bin/${mame}";
|
|
};
|
|
|
|
systemd.services.mame = {
|
|
description = "MAME TUN/TAP Ethernet interface";
|
|
after = [ "network.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
path = [ pkgs.iproute2 ];
|
|
serviceConfig = {
|
|
Type = "oneshot";
|
|
RemainAfterExit = true;
|
|
ExecStart = "${pkgs.mame}/bin/taputil.sh -c ${cfg.user} ${cfg.emuAddr} ${cfg.hostAddr} -";
|
|
ExecStop = "${pkgs.mame}/bin/taputil.sh -d ${cfg.user}";
|
|
};
|
|
};
|
|
};
|
|
|
|
meta.maintainers = [ ];
|
|
}
|