mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-22 12:53:54 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
55 lines
1.6 KiB
Nix
55 lines
1.6 KiB
Nix
{ stdenv, lib, fetchurl, fetchzip, jdk11, makeWrapper, makeDesktopItem, copyDesktopItems }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "conduktor";
|
|
version = "2.15.1";
|
|
|
|
src = fetchzip {
|
|
url = "https://github.com/conduktor/builds/releases/download/v${version}/Conduktor-linux-${version}.zip";
|
|
sha256 = "sha256-9y/7jni5zIITUWd75AxsfG/b5vCYotmeMeC9aYM2WEs=";
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper copyDesktopItems ];
|
|
|
|
desktopItems = [
|
|
(makeDesktopItem {
|
|
type = "Application";
|
|
name = pname;
|
|
desktopName = "Conduktor";
|
|
genericName = meta.description;
|
|
exec = pname;
|
|
icon = fetchurl {
|
|
url = "https://github.com/conduktor/builds/raw/v${version}/.github/resources/Conduktor.png";
|
|
sha256 = "0s7p74qclvac8xj2m22gfxx5m2c7cf0nqpk5sb049p2wvryhn2j4";
|
|
};
|
|
comment = "A beautiful and fully-featured desktop client for Apache Kafka";
|
|
})
|
|
];
|
|
|
|
dontConfigure = true;
|
|
dontBuild = true;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/share/applications
|
|
mv * $out
|
|
wrapProgram "$out/bin/conduktor" --set JAVA_HOME "${jdk11.home}"
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Apache Kafka Desktop Client";
|
|
longDescription = ''
|
|
Conduktor is a GUI over the Kafka ecosystem, to make the development
|
|
and management of Apache Kafka clusters as easy as possible.
|
|
'';
|
|
homepage = "https://www.conduktor.io/";
|
|
changelog = "https://www.conduktor.io/changelog/#${version}";
|
|
license = licenses.unfree;
|
|
maintainers = with maintainers; [ trobert ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|