mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-09 06:23:36 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
61 lines
2.0 KiB
Nix
61 lines
2.0 KiB
Nix
{ lib, stdenv, fetchurl, perl, openldap, pam, db, cyrus_sasl, libcap
|
|
, expat, libxml2, openssl, pkg-config, systemd
|
|
, cppunit
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "squid";
|
|
version = "6.10";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.squid-cache.org/Versions/v6/squid-${finalAttrs.version}.tar.xz";
|
|
hash = "sha256-Cwexh+cj8Edw3SW+uJrsEgMKFYaWqoiS2HyLJoU0CKc=";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
buildInputs = [
|
|
perl openldap db cyrus_sasl expat libxml2 openssl
|
|
] ++ lib.optionals stdenv.hostPlatform.isLinux [ libcap pam systemd ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
configureFlags = [
|
|
"--enable-ipv6"
|
|
"--disable-strict-error-checking"
|
|
"--disable-arch-native"
|
|
"--with-openssl"
|
|
"--enable-ssl-crtd"
|
|
"--enable-storeio=ufs,aufs,diskd,rock"
|
|
"--enable-removal-policies=lru,heap"
|
|
"--enable-delay-pools"
|
|
"--enable-x-accelerator-vary"
|
|
"--enable-htcp"
|
|
] ++ lib.optional (stdenv.hostPlatform.isLinux && !stdenv.hostPlatform.isMusl)
|
|
"--enable-linux-netfilter";
|
|
|
|
doCheck = true;
|
|
nativeCheckInputs = [ cppunit ];
|
|
preCheck = ''
|
|
# tests attempt to copy around "/bin/true" to make some things
|
|
# no-ops but this doesn't work if our "true" is a multi-call
|
|
# binary, so make our own fake "true" which will work when used
|
|
# this way
|
|
echo "#!$SHELL" > fake-true
|
|
chmod +x fake-true
|
|
grep -rlF '/bin/true' test-suite/ | while read -r filename ; do
|
|
substituteInPlace "$filename" \
|
|
--replace "$(type -P true)" "$(realpath fake-true)" \
|
|
--replace "/bin/true" "$(realpath fake-true)"
|
|
done
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Caching proxy for the Web supporting HTTP, HTTPS, FTP, and more";
|
|
homepage = "http://www.squid-cache.org";
|
|
license = licenses.gpl2Plus;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ raskin ];
|
|
knownVulnerabilities = [ "Squid has multiple unresolved security vulnerabilities, for more information see https://megamansec.github.io/Squid-Security-Audit/" ];
|
|
};
|
|
})
|