mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-21 05:04:00 +00:00
71 lines
1.8 KiB
Nix
71 lines
1.8 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, fetchzip, installShellFiles }:
|
|
|
|
let
|
|
version = "0.27.3";
|
|
sha256 = "08ax1033456hfm5qz0r671xm5ig0047nqp7xffyn9za498bm4i5q";
|
|
manifestsSha256 = "165kspq10nvlihcb1460qmbw5r1mlzs5gliw01qa4mymvzmlggk7";
|
|
|
|
manifests = fetchzip {
|
|
url =
|
|
"https://github.com/fluxcd/flux2/releases/download/v${version}/manifests.tar.gz";
|
|
sha256 = manifestsSha256;
|
|
stripRoot = false;
|
|
};
|
|
|
|
in buildGoModule rec {
|
|
pname = "fluxcd";
|
|
inherit version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "fluxcd";
|
|
repo = "flux2";
|
|
rev = "v${version}";
|
|
inherit sha256;
|
|
};
|
|
|
|
vendorSha256 = "sha256-ENSfec7iSKOkILgVCVnORpAia4D+vBjQAUXDA7EIvVQ=";
|
|
|
|
postUnpack = ''
|
|
cp -r ${manifests} source/cmd/flux/manifests
|
|
'';
|
|
|
|
patches = [ ./patches/disable-tests-ssh_key.patch ];
|
|
|
|
ldflags = [ "-s" "-w" "-X main.VERSION=${version}" ];
|
|
|
|
subPackages = [ "cmd/flux" ];
|
|
|
|
# Required to workaround test error:
|
|
# panic: mkdir /homeless-shelter: permission denied
|
|
HOME = "$TMPDIR";
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
doInstallCheck = true;
|
|
installCheckPhase = ''
|
|
$out/bin/flux --version | grep ${version} > /dev/null
|
|
'';
|
|
|
|
postInstall = ''
|
|
for shell in bash fish zsh; do
|
|
$out/bin/flux completion $shell > flux.$shell
|
|
installShellCompletion flux.$shell
|
|
done
|
|
'';
|
|
|
|
passthru.updateScript = ./update.sh;
|
|
|
|
meta = with lib; {
|
|
description =
|
|
"Open and extensible continuous delivery solution for Kubernetes";
|
|
longDescription = ''
|
|
Flux is a tool for keeping Kubernetes clusters in sync
|
|
with sources of configuration (like Git repositories), and automating
|
|
updates to configuration when there is new code to deploy.
|
|
'';
|
|
homepage = "https://fluxcd.io";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ jlesquembre bryanasdev000 ];
|
|
};
|
|
}
|