mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-02 19:14:14 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
143 lines
3.1 KiB
Nix
143 lines
3.1 KiB
Nix
{
|
|
lib,
|
|
SDL2,
|
|
alsa-lib,
|
|
cmake,
|
|
fetchFromGitHub,
|
|
gtkmm3,
|
|
libGL,
|
|
libX11,
|
|
libXdmcp,
|
|
libXext,
|
|
libXinerama,
|
|
libXrandr,
|
|
libXv,
|
|
libepoxy,
|
|
libpng,
|
|
libselinux,
|
|
minizip,
|
|
ninja,
|
|
pcre2,
|
|
pkg-config,
|
|
portaudio,
|
|
pulseaudio,
|
|
python3,
|
|
stdenv,
|
|
util-linuxMinimal,
|
|
wrapGAppsHook3,
|
|
zlib,
|
|
# Boolean flags
|
|
withGtk ? false,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "snes9x" + lib.optionalString withGtk "-gtk";
|
|
version = "1.63";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "snes9xgit";
|
|
repo = "snes9x";
|
|
rev = finalAttrs.version;
|
|
fetchSubmodules = true;
|
|
hash = "sha256-INMVyB3alwmsApO7ToAaUWgh7jlg2MeLxqHCEnUO88U=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
python3
|
|
]
|
|
++ lib.optionals withGtk [
|
|
cmake
|
|
ninja
|
|
wrapGAppsHook3
|
|
];
|
|
|
|
buildInputs = [
|
|
libX11
|
|
libXv
|
|
minizip
|
|
zlib
|
|
]
|
|
++ lib.optionals stdenv.hostPlatform.isLinux [
|
|
alsa-lib
|
|
pulseaudio
|
|
libselinux
|
|
util-linuxMinimal # provides libmount
|
|
]
|
|
++ lib.optionals (!withGtk) [
|
|
libpng
|
|
libXext
|
|
libXinerama
|
|
]
|
|
++ lib.optionals withGtk [
|
|
gtkmm3
|
|
libepoxy
|
|
libXdmcp
|
|
libXrandr
|
|
pcre2
|
|
portaudio
|
|
SDL2
|
|
];
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
configureFlags = lib.optionals stdenv.hostPlatform.sse4_1Support [
|
|
"--enable-sse41"
|
|
]
|
|
++ lib.optionals stdenv.hostPlatform.avx2Support [
|
|
"--enable-avx2"
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteInPlace external/glad/src/egl.c \
|
|
--replace-fail libEGL.so.1 "${lib.getLib libGL}/lib/libEGL.so.1"
|
|
substituteInPlace external/glad/src/glx.c \
|
|
--replace-fail libGL.so.1 ${lib.getLib libGL}/lib/libGL.so.1
|
|
'';
|
|
|
|
preConfigure = ''
|
|
cd ${if withGtk then "gtk" else "unix"}
|
|
'';
|
|
|
|
installPhase = lib.optionalString (!withGtk) ''
|
|
runHook preInstall
|
|
|
|
install -Dm755 snes9x -t "$out/bin/"
|
|
install -Dm644 snes9x.conf.default -t "$out/share/doc/${finalAttrs.pname}/"
|
|
install -Dm644 ../docs/{control-inputs,controls,snapshots}.txt -t \
|
|
"$out/share/doc/${finalAttrs.pname}/"
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = let
|
|
interface = if withGtk then "GTK" else "X11";
|
|
in
|
|
{
|
|
homepage = "https://www.snes9x.com";
|
|
description = "Super Nintendo Entertainment System (SNES) emulator, ${interface} version";
|
|
longDescription = ''
|
|
Snes9x is a portable, freeware Super Nintendo Entertainment System (SNES)
|
|
emulator. It basically allows you to play most games designed for the SNES
|
|
and Super Famicom Nintendo game systems on your PC or Workstation; which
|
|
includes some real gems that were only ever released in Japan.
|
|
|
|
Version build with ${interface} interface.
|
|
'';
|
|
license = lib.licenses.unfreeRedistributable // {
|
|
url = "https://github.com/snes9xgit/snes9x/blob/${finalAttrs.src.rev}/LICENSE";
|
|
};
|
|
mainProgram = "snes9x";
|
|
maintainers = with lib.maintainers; [
|
|
AndersonTorres
|
|
qknight
|
|
thiagokokada
|
|
sugar700
|
|
];
|
|
platforms = lib.platforms.unix;
|
|
broken = (withGtk && stdenv.hostPlatform.isDarwin);
|
|
};
|
|
})
|