mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-02 11:03:57 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
48 lines
1.4 KiB
Nix
48 lines
1.4 KiB
Nix
{ lib, stdenv, fetchFromGitHub, makeWrapper }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "rolespec";
|
|
version = "20161104";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "nickjj";
|
|
repo = "rolespec";
|
|
rev = "d9ee530cd709168882059776c482fc37f46cb743";
|
|
sha256 = "1jkidw6aqr0zfqwmcvlpi9qa140z2pxcfsd43xm5ikx6jcwjdrzl";
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
# The default build phase (`make`) runs the test code. It's difficult to do
|
|
# the test in the build environment because it depends on the system package
|
|
# managers (apt/yum/pacman). We simply skip this phase since RoleSpec is
|
|
# shell based.
|
|
dontBuild = true;
|
|
|
|
# Wrap the program because `ROLESPEC_LIB` defaults to
|
|
# `/usr/local/lib/rolespec`.
|
|
installPhase = ''
|
|
make install PREFIX=$out
|
|
wrapProgram $out/bin/rolespec --set ROLESPEC_LIB $out/lib/rolespec
|
|
'';
|
|
|
|
# Since RoleSpec installs the shell script files in `lib` directory, the
|
|
# fixup phase shows some warnings. Disable these actions.
|
|
dontPatchELF = true;
|
|
dontStrip = true;
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/nickjj/rolespec";
|
|
description = "Test library for testing Ansible roles";
|
|
mainProgram = "rolespec";
|
|
longDescription = ''
|
|
A shell based test library for Ansible that works both locally and over
|
|
Travis-CI.
|
|
'';
|
|
downloadPage = "https://github.com/nickjj/rolespec";
|
|
license = licenses.gpl3;
|
|
maintainers = [ maintainers.dochang ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|