mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-03 19:43:30 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
57 lines
1.6 KiB
Nix
57 lines
1.6 KiB
Nix
{ lib, stdenv, fetchurl, perl, kbd, bdftopcf
|
|
, libfaketime, xorg
|
|
}:
|
|
|
|
stdenv.mkDerivation {
|
|
name = "uni-vga";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.inp.nsk.su/~bolkhov/files/fonts/univga/uni-vga.tgz";
|
|
sha256 = "05sns8h5yspa7xkl81ri7y1yxf5icgsnl497f3xnaryhx11s2rv6";
|
|
};
|
|
|
|
nativeBuildInputs =
|
|
[ bdftopcf libfaketime
|
|
xorg.fonttosfnt xorg.mkfontscale
|
|
] ++ lib.optionals stdenv.hostPlatform.isLinux [ perl kbd ];
|
|
|
|
postPatch = "patchShebangs .";
|
|
|
|
buildPhase = ''
|
|
# convert font to compressed pcf
|
|
bdftopcf u_vga16.bdf | gzip -c -9 -n > u_vga16.pcf.gz
|
|
|
|
# convert bdf font to otb
|
|
faketime -f "1970-01-01 00:00:01" \
|
|
fonttosfnt -v -o u_vga16.otb u_vga16.bdf
|
|
'' + lib.optionalString stdenv.hostPlatform.isLinux ''
|
|
# convert font to compressed psf
|
|
./bdf2psf.pl -s UniCyrX.sfm u_vga16.bdf \
|
|
| psfaddtable - UniCyrX.sfm - \
|
|
| gzip -c -9 -n > u_vga16.psf.gz
|
|
'';
|
|
|
|
installPhase = ''
|
|
# install pcf and otb (for X11 and GTK applications)
|
|
install -m 644 -D *.otb *.pcf.gz -t "$out/share/fonts"
|
|
mkfontdir "$out/share/fonts"
|
|
|
|
# install bdf font
|
|
install -m 644 -D *.bdf -t "$bdf/share/fonts"
|
|
mkfontdir "$bdf/share/fonts"
|
|
|
|
'' + lib.optionalString stdenv.hostPlatform.isLinux ''
|
|
# install psf (for linux virtual terminal)
|
|
install -m 644 -D *.psf.gz -t "$out/share/consolefonts"
|
|
'';
|
|
|
|
outputs = [ "out" "bdf" ];
|
|
|
|
meta = with lib; {
|
|
description = "Unicode VGA font";
|
|
maintainers = [ maintainers.ftrvxmtrx ];
|
|
homepage = "http://www.inp.nsk.su/~bolkhov/files/fonts/univga/";
|
|
license = licenses.mit;
|
|
};
|
|
}
|