mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-24 22:04:20 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
68 lines
2.0 KiB
Nix
68 lines
2.0 KiB
Nix
{ stdenv, fetchFromGitHub, cmake, jsoncpp, libossp_uuid, zlib, lib
|
|
# optional but of negligible size
|
|
, openssl, brotli, c-ares
|
|
# optional databases
|
|
, sqliteSupport ? true, sqlite
|
|
, postgresSupport ? false, postgresql
|
|
, redisSupport ? false, hiredis
|
|
, mysqlSupport ? false, libmysqlclient, mariadb }:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "drogon";
|
|
version = "1.9.8";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "drogonframework";
|
|
repo = "drogon";
|
|
rev = "v${finalAttrs.version}";
|
|
hash = "sha256-vQ9d3l++waYTYt+bvt/ShatBVxTfA7LmYIXV5VSraNQ=";
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
nativeBuildInputs = [ cmake ];
|
|
|
|
cmakeFlags = [
|
|
(lib.cmakeBool "BUILD_TESTING" finalAttrs.finalPackage.doInstallCheck)
|
|
(lib.cmakeBool "BUILD_EXAMPLES" false)
|
|
];
|
|
|
|
propagatedBuildInputs = [
|
|
jsoncpp
|
|
libossp_uuid
|
|
zlib
|
|
openssl
|
|
brotli
|
|
c-ares
|
|
] ++ lib.optional sqliteSupport sqlite
|
|
++ lib.optional postgresSupport postgresql
|
|
++ lib.optional redisSupport hiredis
|
|
# drogon uses mariadb for mysql (see https://github.com/drogonframework/drogon/wiki/ENG-02-Installation#Library-Dependencies)
|
|
++ lib.optionals mysqlSupport [ libmysqlclient mariadb ];
|
|
|
|
patches = [
|
|
# this part of the test would normally fail because it attempts to configure a CMake project that uses find_package on itself
|
|
# this patch makes drogon and trantor visible to the test
|
|
./fix_find_package.patch
|
|
];
|
|
|
|
# modifying PATH here makes drogon_ctl visible to the test
|
|
installCheckPhase = ''
|
|
(
|
|
cd ..
|
|
PATH=$PATH:$out/bin $SHELL test.sh
|
|
)
|
|
'';
|
|
|
|
# this excludes you, pkgsStatic (cmake wants to run built binaries
|
|
# in the buildPhase)
|
|
doInstallCheck = stdenv.buildPlatform == stdenv.hostPlatform;
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/drogonframework/drogon";
|
|
description = "C++14/17 based HTTP web application framework";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ urlordjames ];
|
|
platforms = platforms.all;
|
|
};
|
|
})
|