mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-22 15:03:28 +00:00
4cac65085c
Without the change the build fails as:
$ nix build --impure --expr 'with import ./. {}; procps.override { withSystemd = false; watchOnly = true; }' -L
...
procps> build flags: -j16 SHELL=.../bash usrbin_execdir=\$\(out\)/bin watch PKG_LDFLAGS=
procps> make: *** No rule to make target 'watch'. Stop.
While at it dropped unused `PKG_LDFLAGS=` flag.
71 lines
2.2 KiB
Nix
71 lines
2.2 KiB
Nix
{ lib
|
||
, stdenv
|
||
, fetchurl
|
||
, ncurses
|
||
, pkg-config
|
||
, autoreconfHook
|
||
|
||
# `ps` with systemd support is able to properly report different
|
||
# attributes like unit name, so we want to have it on linux.
|
||
, withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd
|
||
, systemd
|
||
|
||
# procps is mostly Linux-only. Most commands require a running Linux
|
||
# system (or very similar like that found in Cygwin). The one
|
||
# exception is ‘watch’ which is portable enough to run on pretty much
|
||
# any UNIX-compatible system.
|
||
, watchOnly ? !(stdenv.hostPlatform.isLinux || stdenv.hostPlatform.isCygwin)
|
||
|
||
, binlore
|
||
, procps
|
||
}:
|
||
|
||
stdenv.mkDerivation rec {
|
||
pname = "procps";
|
||
version = "4.0.4";
|
||
|
||
# The project's releases are on SF, but git repo on gitlab.
|
||
src = fetchurl {
|
||
url = "mirror://sourceforge/procps-ng/procps-ng-${version}.tar.xz";
|
||
hash = "sha256-IocNb+skeK22F85PCaeHrdry0mDFqKp7F9iJqWLF5C4=";
|
||
};
|
||
|
||
buildInputs = [ ncurses ]
|
||
++ lib.optional withSystemd systemd;
|
||
nativeBuildInputs = [ pkg-config autoreconfHook ];
|
||
|
||
makeFlags = [ "usrbin_execdir=$(out)/bin" ]
|
||
++ lib.optionals watchOnly [ "src/watch" ];
|
||
|
||
enableParallelBuilding = true;
|
||
|
||
# Too red; 8bit support for fixing https://github.com/NixOS/nixpkgs/issues/275220
|
||
configureFlags = [ "--disable-modern-top" "--enable-watch8bit" ]
|
||
++ lib.optional withSystemd "--with-systemd"
|
||
++ lib.optional stdenv.hostPlatform.isMusl "--disable-w"
|
||
++ lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
|
||
"ac_cv_func_malloc_0_nonnull=yes"
|
||
"ac_cv_func_realloc_0_nonnull=yes"
|
||
];
|
||
|
||
installPhase = lib.optionalString watchOnly ''
|
||
install -m 0755 -D src/watch $out/bin/watch
|
||
install -m 0644 -D man/watch.1 $out/share/man/man1/watch.1
|
||
'';
|
||
|
||
# no obvious exec in documented arguments; haven't trawled source
|
||
# to figure out what exec binlore hits on
|
||
passthru.binlore.out = binlore.synthesize procps ''
|
||
execer cannot bin/{ps,top,free}
|
||
'';
|
||
|
||
meta = with lib; {
|
||
homepage = "https://gitlab.com/procps-ng/procps";
|
||
description = "Utilities that give information about processes using the /proc filesystem";
|
||
priority = 11; # less than coreutils, which also provides "kill" and "uptime"
|
||
license = licenses.gpl2Plus;
|
||
platforms = platforms.unix;
|
||
maintainers = [ ];
|
||
};
|
||
}
|