mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-16 09:54:52 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
97 lines
2.3 KiB
Nix
97 lines
2.3 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
buildPythonPackage,
|
|
pythonOlder,
|
|
fetchFromGitHub,
|
|
substituteAll,
|
|
alsa-utils,
|
|
libnotify,
|
|
which,
|
|
poetry-core,
|
|
jeepney,
|
|
loguru,
|
|
pytest,
|
|
dbus,
|
|
coreutils,
|
|
}:
|
|
|
|
buildPythonPackage rec {
|
|
pname = "notify-py";
|
|
version = "0.3.43";
|
|
format = "pyproject";
|
|
|
|
disabled = pythonOlder "3.6";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ms7m";
|
|
repo = pname;
|
|
rev = "refs/tags/v${version}";
|
|
hash = "sha256-4PJ/0dLG3bWDuF1G/qUmvNaIUFXgPP2S/0uhZz86WRA=";
|
|
};
|
|
|
|
patches =
|
|
lib.optionals stdenv.hostPlatform.isLinux [
|
|
# hardcode paths to aplay and notify-send
|
|
(substituteAll {
|
|
src = ./linux-paths.patch;
|
|
aplay = "${alsa-utils}/bin/aplay";
|
|
notifysend = "${libnotify}/bin/notify-send";
|
|
})
|
|
]
|
|
++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
# hardcode path to which
|
|
(substituteAll {
|
|
src = ./darwin-paths.patch;
|
|
which = "${which}/bin/which";
|
|
})
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
poetry-core
|
|
];
|
|
|
|
pythonRelaxDeps = [ "loguru" ];
|
|
|
|
propagatedBuildInputs = [ loguru ] ++ lib.optionals stdenv.hostPlatform.isLinux [ jeepney ];
|
|
|
|
nativeCheckInputs = [ pytest ] ++ lib.optionals stdenv.hostPlatform.isLinux [ dbus ];
|
|
|
|
checkPhase =
|
|
if stdenv.hostPlatform.isDarwin then
|
|
''
|
|
# Tests search for "afplay" binary which is built in to macOS and not available in nixpkgs
|
|
mkdir $TMP/bin
|
|
ln -s ${coreutils}/bin/true $TMP/bin/afplay
|
|
PATH="$TMP/bin:$PATH" pytest
|
|
''
|
|
else if stdenv.hostPlatform.isLinux then
|
|
''
|
|
dbus-run-session \
|
|
--config-file=${dbus}/share/dbus-1/session.conf \
|
|
pytest
|
|
''
|
|
else
|
|
''
|
|
pytest
|
|
'';
|
|
|
|
# GDBus.Error:org.freedesktop.DBus.Error.ServiceUnknown: The name
|
|
# org.freedesktop.Notifications was not provided by any .service files
|
|
doCheck = false;
|
|
|
|
pythonImportsCheck = [ "notifypy" ];
|
|
|
|
meta = with lib; {
|
|
description = "Cross-platform desktop notification library for Python";
|
|
mainProgram = "notifypy";
|
|
homepage = "https://github.com/ms7m/notify-py";
|
|
changelog = "https://github.com/ms7m/notify-py/releases/tag/v${version}";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [
|
|
austinbutler
|
|
dotlambda
|
|
];
|
|
};
|
|
}
|