mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 08:33:54 +00:00
1a047c4a8e
This is useful for use-cases like this (logging to journald):
```
programs.sway.extraSessionCommands = ''
if [ -z "$_SWAY_DID_SYSTEMD_CAT" ]; then
export _SWAY_DID_SYSTEMD_CAT=1
exec ${config.systemd.package}/bin/systemd-cat -t sway "$0" "$@"
fi
# ... (potentially also another exec)
'';
```
Without this change the rest of the extraSessionCommands won't be
executed after the exec since the whole extraSessionCommands block would
be skipped during the re-execution (_SWAY_WRAPPER_ALREADY_EXECUTED is
already set).
52 lines
1.5 KiB
Nix
52 lines
1.5 KiB
Nix
{ lib, stdenv
|
|
, sway-unwrapped, swaybg
|
|
, makeWrapper, symlinkJoin, writeShellScriptBin
|
|
, withBaseWrapper ? true, extraSessionCommands ? "", dbus
|
|
, withGtkWrapper ? false, wrapGAppsHook, gdk-pixbuf
|
|
, extraOptions ? [] # E.g.: [ "--verbose" ]
|
|
}:
|
|
|
|
assert extraSessionCommands != "" -> withBaseWrapper;
|
|
|
|
with lib;
|
|
|
|
let
|
|
baseWrapper = writeShellScriptBin "sway" ''
|
|
set -o errexit
|
|
if [ ! "$_SWAY_WRAPPER_ALREADY_EXECUTED" ]; then
|
|
${extraSessionCommands}
|
|
export _SWAY_WRAPPER_ALREADY_EXECUTED=1
|
|
fi
|
|
if [ "$DBUS_SESSION_BUS_ADDRESS" ]; then
|
|
export DBUS_SESSION_BUS_ADDRESS
|
|
exec ${sway-unwrapped}/bin/sway "$@"
|
|
else
|
|
exec ${dbus}/bin/dbus-run-session ${sway-unwrapped}/bin/sway "$@"
|
|
fi
|
|
'';
|
|
in symlinkJoin {
|
|
name = "sway-${sway-unwrapped.version}";
|
|
|
|
paths = (optional withBaseWrapper baseWrapper)
|
|
++ [ sway-unwrapped ];
|
|
|
|
nativeBuildInputs = [ makeWrapper ]
|
|
++ (optional withGtkWrapper wrapGAppsHook);
|
|
|
|
buildInputs = optional withGtkWrapper gdk-pixbuf;
|
|
|
|
postBuild = ''
|
|
# We want to run wrapProgram manually to only wrap sway and add swaybg:
|
|
export dontWrapGApps=true
|
|
${optionalString withGtkWrapper "wrapGAppsHook"}
|
|
wrapProgram $out/bin/sway \
|
|
--prefix PATH : "${swaybg}/bin" \
|
|
${optionalString withGtkWrapper ''"''${gappsWrapperArgs[@]}"''} \
|
|
${optionalString (extraOptions != []) "${concatMapStrings (x: " --add-flags " + x) extraOptions}"}
|
|
'';
|
|
|
|
passthru.providedSessions = [ "sway" ];
|
|
|
|
inherit (sway-unwrapped) meta;
|
|
}
|