mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-14 01:33:10 +00:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
77 lines
1.9 KiB
Nix
77 lines
1.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
defaultUserGroup = "usbmux";
|
|
apple = "05ac";
|
|
|
|
cfg = config.services.usbmuxd;
|
|
|
|
in
|
|
|
|
{
|
|
options.services.usbmuxd = {
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Enable the usbmuxd ("USB multiplexing daemon") service. This daemon is
|
|
in charge of multiplexing connections over USB to an iOS device. This is
|
|
needed for transferring data from and to iOS devices (see ifuse). Also
|
|
this may enable plug-n-play tethering for iPhones.
|
|
'';
|
|
};
|
|
|
|
user = mkOption {
|
|
type = types.str;
|
|
default = defaultUserGroup;
|
|
description = lib.mdDoc ''
|
|
The user usbmuxd should use to run after startup.
|
|
'';
|
|
};
|
|
|
|
group = mkOption {
|
|
type = types.str;
|
|
default = defaultUserGroup;
|
|
description = lib.mdDoc ''
|
|
The group usbmuxd should use to run after startup.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
users.users = optionalAttrs (cfg.user == defaultUserGroup) {
|
|
${cfg.user} = {
|
|
description = "usbmuxd user";
|
|
group = cfg.group;
|
|
isSystemUser = true;
|
|
};
|
|
};
|
|
|
|
users.groups = optionalAttrs (cfg.group == defaultUserGroup) {
|
|
${cfg.group} = { };
|
|
};
|
|
|
|
# Give usbmuxd permission for Apple devices
|
|
services.udev.extraRules = ''
|
|
SUBSYSTEM=="usb", ATTR{idVendor}=="${apple}", GROUP="${cfg.group}"
|
|
'';
|
|
|
|
systemd.services.usbmuxd = {
|
|
description = "usbmuxd";
|
|
wantedBy = [ "multi-user.target" ];
|
|
unitConfig.Documentation = "man:usbmuxd(8)";
|
|
serviceConfig = {
|
|
# Trigger the udev rule manually. This doesn't require replugging the
|
|
# device when first enabling the option to get it to work
|
|
ExecStartPre = "${pkgs.udev}/bin/udevadm trigger -s usb -a idVendor=${apple}";
|
|
ExecStart = "${pkgs.usbmuxd}/bin/usbmuxd -U ${cfg.user} -f";
|
|
};
|
|
};
|
|
|
|
};
|
|
}
|