mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-30 16:53:40 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
52 lines
1.6 KiB
Nix
52 lines
1.6 KiB
Nix
{ lib, stdenv, fetchFromGitHub, fetchpatch, autoreconfHook, pkg-config, libpcap, guile_2_2, openssl }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "junkie";
|
|
version = "2.8.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "rixed";
|
|
repo = "junkie";
|
|
rev = "v${version}";
|
|
sha256 = "0kfdjgch667gfb3qpiadd2dj3fxc7r19nr620gffb1ahca02wq31";
|
|
};
|
|
|
|
patches = [
|
|
# Pull upstream patch for -fno-common toolchains:
|
|
(fetchpatch {
|
|
name = "fno-common.patch";
|
|
url = "https://github.com/rixed/junkie/commit/52209c5b0c9a09981739ede9701cd73e82a88ea5.patch";
|
|
sha256 = "1qg01jinqn5wr2mz77rzaidnrli35di0k7lnx6kfm7dh7v8kxbrr";
|
|
})
|
|
];
|
|
|
|
# IP_DONTFRAG is defined on macOS from Big Sur
|
|
postPatch = lib.optionalString (lib.versionAtLeast stdenv.hostPlatform.darwinMinVersion "11") ''
|
|
sed -i '10i#undef IP_DONTFRAG' include/junkie/proto/ip.h
|
|
'';
|
|
|
|
buildInputs = [ libpcap guile_2_2 openssl ];
|
|
nativeBuildInputs = [ autoreconfHook pkg-config ];
|
|
configureFlags = [
|
|
"GUILELIBDIR=\${out}/${guile_2_2.siteDir}"
|
|
"GUILECACHEDIR=\${out}/${guile_2_2.siteCcacheDir}"
|
|
];
|
|
|
|
meta = {
|
|
description = "Deep packet inspection swiss-army knife";
|
|
homepage = "https://github.com/rixed/junkie";
|
|
license = lib.licenses.agpl3Plus;
|
|
maintainers = [ lib.maintainers.rixed ];
|
|
platforms = lib.platforms.unix;
|
|
longDescription = ''
|
|
Junkie is a network sniffer like Tcpdump or Wireshark, but designed to
|
|
be easy to program and extend.
|
|
|
|
It comes with several command line tools to demonstrate this:
|
|
- a packet dumper;
|
|
- a nettop tool;
|
|
- a tool listing TLS certificates...
|
|
'';
|
|
};
|
|
}
|