mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 04:53:27 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
83 lines
1.6 KiB
Nix
83 lines
1.6 KiB
Nix
{ lib
|
|
, fetchFromGitHub
|
|
, glibcLocales
|
|
, glib-networking
|
|
, gobject-introspection
|
|
, gtk3
|
|
, libnotify
|
|
, python3Packages
|
|
, steam-run
|
|
, substituteAll
|
|
, unzip
|
|
, webkitgtk_4_0
|
|
, wrapGAppsHook3
|
|
}:
|
|
|
|
python3Packages.buildPythonApplication rec {
|
|
pname = "minigalaxy";
|
|
version = "1.3.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "sharkwouter";
|
|
repo = "minigalaxy";
|
|
rev = "refs/tags/${version}";
|
|
hash = "sha256-CMPBKnNrcjHVpsbBjY97FiygEJNG9jKHR/LoVMfuxG4=";
|
|
};
|
|
|
|
patches = [
|
|
(substituteAll {
|
|
src = ./inject-launcher-steam-run.diff;
|
|
steamrun = lib.getExe steam-run;
|
|
})
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteInPlace minigalaxy/installer.py \
|
|
--replace-fail '"unzip"' "\"${lib.getExe unzip}\"" \
|
|
--replace-fail "'unzip'" "\"${lib.getExe unzip}\""
|
|
'';
|
|
|
|
nativeBuildInputs = [
|
|
wrapGAppsHook3
|
|
gobject-introspection
|
|
];
|
|
|
|
buildInputs = [
|
|
glib-networking
|
|
gtk3
|
|
libnotify
|
|
];
|
|
|
|
nativeCheckInputs = with python3Packages; [
|
|
glibcLocales
|
|
pytestCheckHook
|
|
simplejson
|
|
];
|
|
|
|
preCheck = ''
|
|
export HOME=$(mktemp -d)
|
|
'';
|
|
|
|
pythonPath = [
|
|
python3Packages.pygobject3
|
|
python3Packages.requests
|
|
webkitgtk_4_0
|
|
];
|
|
|
|
dontWrapGApps = true;
|
|
|
|
preFixup = ''
|
|
makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://sharkwouter.github.io/minigalaxy/";
|
|
changelog = "https://github.com/sharkwouter/minigalaxy/blob/${version}/CHANGELOG.md";
|
|
downloadPage = "https://github.com/sharkwouter/minigalaxy/releases";
|
|
description = "Simple GOG client for Linux";
|
|
license = licenses.gpl3;
|
|
maintainers = [ ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|