mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 04:53:27 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
52 lines
1.6 KiB
Nix
52 lines
1.6 KiB
Nix
{ fetchurl, lib, stdenv, gettext, npth, libgpg-error, buildPackages, gitUpdater }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libassuan";
|
|
version = "2.5.7";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://gnupg/${pname}/${pname}-${version}.tar.bz2";
|
|
sha256 = "sha256-AQMIH/wng4ouUEeRU8oQXoc9PWXYqVkygunJTH5q+3Y=";
|
|
};
|
|
|
|
outputs = [ "out" "dev" "info" ];
|
|
outputBin = "dev"; # libassuan-config
|
|
|
|
depsBuildBuild = [ buildPackages.stdenv.cc ];
|
|
buildInputs = [ npth gettext ];
|
|
|
|
configureFlags = [
|
|
# Required for cross-compilation.
|
|
"--with-libgpg-error-prefix=${libgpg-error.dev}"
|
|
];
|
|
|
|
doCheck = true;
|
|
|
|
# Make sure includes are fixed for callers who don't use libassuan-config
|
|
postInstall = ''
|
|
sed -i 's,#include <gpg-error.h>,#include "${libgpg-error.dev}/include/gpg-error.h",g' $dev/include/assuan.h
|
|
'';
|
|
|
|
passthru.updateScript = gitUpdater {
|
|
url = "https://dev.gnupg.org/source/libassuan.git";
|
|
rev-prefix = "libassuan-";
|
|
ignoredVersions = ".*-base";
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "IPC library used by GnuPG and related software";
|
|
mainProgram = "libassuan-config";
|
|
longDescription = ''
|
|
Libassuan is a small library implementing the so-called Assuan
|
|
protocol. This protocol is used for IPC between most newer
|
|
GnuPG components. Both, server and client side functions are
|
|
provided.
|
|
'';
|
|
homepage = "https://gnupg.org/software/libassuan/";
|
|
changelog = "https://dev.gnupg.org/source/libassuan/browse/master/NEWS;libassuan-${version}";
|
|
license = licenses.lgpl2Plus;
|
|
platforms = platforms.all;
|
|
maintainers = [ ];
|
|
};
|
|
}
|