mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-16 09:54:52 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
51 lines
1.4 KiB
Nix
51 lines
1.4 KiB
Nix
# slack-cli must be configured using the SLACK_CLI_TOKEN environment variable.
|
|
# Using `slack init` will not work because it tries to write to the Nix store.
|
|
#
|
|
# There is no reason that we couldn't change the file path that slack-cli uses
|
|
# for token storage, except that it would make the Nix package inconsistent with
|
|
# upstream and other distributions.
|
|
|
|
{ stdenv, lib, fetchFromGitHub, curl, jq, coreutils, gnugrep, gnused
|
|
, runtimeShell }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "slack-cli";
|
|
version = "0.18.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "rockymadden";
|
|
repo = "slack-cli";
|
|
rev = "v${version}";
|
|
sha256 = "022yr3cpfg0v7cxi62zzk08vp0l3w851qpfh6amyfgjiynnfyddl";
|
|
};
|
|
|
|
dontBuild = true;
|
|
|
|
installPhase = ''
|
|
mkdir -p "$out/bin"
|
|
cp src/slack "$out/bin/.slack-wrapped"
|
|
|
|
cat <<-WRAPPER > "$out/bin/slack"
|
|
#!${runtimeShell}
|
|
[ "\$1" = "init" -a -z "\$SLACK_CLI_TOKEN" ] && cat <<-'MESSAGE' >&2
|
|
WARNING: slack-cli must be configured using the SLACK_CLI_TOKEN
|
|
environment variable. Using \`slack init\` will not work because it tries
|
|
to write to the Nix store.
|
|
|
|
MESSAGE
|
|
|
|
export PATH=${lib.makeBinPath [ curl jq coreutils gnugrep gnused ]}:"\$PATH"
|
|
exec "$out/bin/.slack-wrapped" "\$@"
|
|
WRAPPER
|
|
|
|
chmod +x "$out/bin/slack"
|
|
'';
|
|
|
|
meta = {
|
|
license = lib.licenses.mit;
|
|
maintainers = [ ];
|
|
mainProgram = "slack";
|
|
platforms = lib.platforms.unix;
|
|
};
|
|
}
|