mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-29 09:04:17 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
52 lines
1.2 KiB
Nix
52 lines
1.2 KiB
Nix
{ buildGoModule, fetchFromGitHub, lib, symlinkJoin }:
|
|
let
|
|
generic = { modRoot, vendorHash }:
|
|
buildGoModule rec {
|
|
pname = "bird-lg-${modRoot}";
|
|
version = "1.3.5";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "xddxdd";
|
|
repo = "bird-lg-go";
|
|
rev = "v${version}";
|
|
hash = "sha256-lWpTIuN+wCSDBHmpRIfVG8Z1Qx1s55MnJomQPjczB5k=";
|
|
};
|
|
|
|
doDist = false;
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
];
|
|
|
|
inherit modRoot vendorHash;
|
|
|
|
meta = with lib; {
|
|
description = "Bird Looking Glass";
|
|
homepage = "https://github.com/xddxdd/bird-lg-go";
|
|
changelog = "https://github.com/xddxdd/bird-lg-go/releases/tag/v${version}";
|
|
license = licenses.gpl3Plus;
|
|
maintainers = with maintainers; [
|
|
tchekda
|
|
e1mo
|
|
];
|
|
};
|
|
};
|
|
|
|
bird-lg-frontend = generic {
|
|
modRoot = "frontend";
|
|
vendorHash = "sha256-+M9Mlqck2E/ETW+NXsKwIeWlmZAaBU07fgDhKUU9PAI=";
|
|
};
|
|
|
|
bird-lg-proxy = generic {
|
|
modRoot = "proxy";
|
|
vendorHash = "sha256-nBTLQUX68f98D0RTlyX0gnvhQ+bu8d3Vv67J/YoXJxs=";
|
|
};
|
|
in
|
|
symlinkJoin {
|
|
name = "bird-lg-${bird-lg-frontend.version}";
|
|
paths = [ bird-lg-frontend bird-lg-proxy ];
|
|
} // {
|
|
inherit (bird-lg-frontend) version meta;
|
|
}
|