mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-04-11 01:37:11 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
92 lines
2.7 KiB
Nix
92 lines
2.7 KiB
Nix
{ lib, stdenv, fetchFromGitHub, fetchpatch2, pkg-config, python3Packages, makeWrapper
|
|
, libsamplerate, libsndfile, readline, eigen, celt
|
|
, wafHook
|
|
# Darwin Dependencies
|
|
, aften, AudioUnit, CoreAudio, libobjc, Accelerate
|
|
|
|
# Optional Dependencies
|
|
, dbus ? null, libffado ? null, alsa-lib ? null
|
|
, libopus ? null
|
|
|
|
# Extra options
|
|
, prefix ? ""
|
|
|
|
, testers
|
|
}:
|
|
|
|
let
|
|
inherit (python3Packages) python dbus-python;
|
|
shouldUsePkg = pkg: if pkg != null && lib.meta.availableOn stdenv.hostPlatform pkg then pkg else null;
|
|
|
|
libOnly = prefix == "lib";
|
|
|
|
optDbus = if stdenv.hostPlatform.isDarwin then null else shouldUsePkg dbus;
|
|
optPythonDBus = if libOnly then null else shouldUsePkg dbus-python;
|
|
optLibffado = if libOnly then null else shouldUsePkg libffado;
|
|
optAlsaLib = if libOnly then null else shouldUsePkg alsa-lib;
|
|
optLibopus = shouldUsePkg libopus;
|
|
in
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "${prefix}jack2";
|
|
version = "1.9.22";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "jackaudio";
|
|
repo = "jack2";
|
|
rev = "v${finalAttrs.version}";
|
|
sha256 = "sha256-Cslfys5fcZDy0oee9/nM5Bd1+Cg4s/ayXjJJOSQCL4E=";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
nativeBuildInputs = [ pkg-config python makeWrapper wafHook ];
|
|
buildInputs = [ libsamplerate libsndfile readline eigen celt
|
|
optDbus optPythonDBus optLibffado optAlsaLib optLibopus
|
|
] ++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
aften AudioUnit CoreAudio Accelerate libobjc
|
|
];
|
|
|
|
patches = [
|
|
(fetchpatch2 {
|
|
# Python 3.12 support
|
|
name = "jack2-waf2.0.26.patch";
|
|
url = "https://github.com/jackaudio/jack2/commit/250420381b1a6974798939ad7104ab1a4b9a9994.patch";
|
|
hash = "sha256-M/H72lLTeddefqth4BSkEfySZRYMIzLErb7nIgVN0u8=";
|
|
})
|
|
];
|
|
|
|
postPatch = ''
|
|
patchShebangs --build svnversion_regenerate.sh
|
|
'';
|
|
|
|
wafConfigureFlags = [
|
|
"--classic"
|
|
"--autostart=${if (optDbus != null) then "dbus" else "classic"}"
|
|
] ++ lib.optional (optDbus != null) "--dbus"
|
|
++ lib.optional (optLibffado != null) "--firewire"
|
|
++ lib.optional (optAlsaLib != null) "--alsa";
|
|
|
|
postInstall = (if libOnly then ''
|
|
rm -rf $out/{bin,share}
|
|
rm -rf $out/lib/{jack,libjacknet*,libjackserver*}
|
|
'' else lib.optionalString (optDbus != null) ''
|
|
wrapProgram $out/bin/jack_control --set PYTHONPATH $PYTHONPATH
|
|
'');
|
|
|
|
postFixup = ''
|
|
substituteInPlace "$dev/lib/pkgconfig/jack.pc" \
|
|
--replace "$out/include" "$dev/include"
|
|
'';
|
|
|
|
passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
|
|
|
|
meta = with lib; {
|
|
description = "JACK audio connection kit, version 2 with jackdbus";
|
|
homepage = "https://jackaudio.org";
|
|
license = licenses.gpl2Plus;
|
|
pkgConfigModules = [ "jack" ];
|
|
platforms = platforms.unix;
|
|
maintainers = [ ];
|
|
};
|
|
})
|