mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-07 14:23:19 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
81 lines
1.8 KiB
Nix
81 lines
1.8 KiB
Nix
{ stdenv
|
|
, lib
|
|
, fetchFromGitHub
|
|
, cmake
|
|
, mpi
|
|
, blas
|
|
, gfortran
|
|
, llvmPackages
|
|
, cudaPackages
|
|
, rocmPackages
|
|
, config
|
|
, gpuBackend ? (
|
|
if config.cudaSupport
|
|
then "cuda"
|
|
else if config.rocmSupport
|
|
then "rocm"
|
|
else "none"
|
|
)
|
|
}:
|
|
|
|
assert builtins.elem gpuBackend [ "none" "cuda" "rocm" ];
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "spla";
|
|
version = "1.6.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "eth-cscs";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
hash = "sha256-fNH1IOKV1Re8G7GH9Xfn3itR80eonTbEGKQRRD16/2k=";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
postPatch = ''
|
|
substituteInPlace src/gpu_util/gpu_blas_api.hpp \
|
|
--replace '#include <rocblas.h>' '#include <rocblas/rocblas.h>'
|
|
'';
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
gfortran
|
|
];
|
|
|
|
buildInputs = [
|
|
blas
|
|
mpi
|
|
]
|
|
++ lib.optional (gpuBackend == "cuda") cudaPackages.cudatoolkit
|
|
++ lib.optionals (gpuBackend == "rocm") [
|
|
rocmPackages.clr
|
|
rocmPackages.rocblas
|
|
] ++ lib.optional stdenv.hostPlatform.isDarwin llvmPackages.openmp
|
|
;
|
|
|
|
cmakeFlags = [
|
|
"-DSPLA_OMP=ON"
|
|
"-DSPLA_FORTRAN=ON"
|
|
"-DSPLA_INSTALL=ON"
|
|
# Required due to broken CMake files
|
|
"-DCMAKE_INSTALL_LIBDIR=lib"
|
|
"-DCMAKE_INSTALL_INCLUDEDIR=include"
|
|
]
|
|
++ lib.optional (gpuBackend == "cuda") "-DSPLA_GPU_BACKEND=CUDA"
|
|
++ lib.optional (gpuBackend == "rocm") [ "-DSPLA_GPU_BACKEND=ROCM" ]
|
|
;
|
|
|
|
preFixup = ''
|
|
substituteInPlace $out/lib/cmake/SPLA/SPLASharedTargets-release.cmake \
|
|
--replace-fail "\''${_IMPORT_PREFIX}" "$out"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Specialized Parallel Linear Algebra, providing distributed GEMM functionality for specific matrix distributions with optional GPU acceleration";
|
|
homepage = "https://github.com/eth-cscs/spla";
|
|
license = licenses.bsd3;
|
|
maintainers = [ maintainers.sheepforce ];
|
|
};
|
|
}
|