mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-26 07:34:11 +00:00
42815b4a0c
Many packages have some kind of flag indicating whether or not to build with
systemd support. Most of these default to `stdenv.isLinux`, but systemd does
not build on (and is marked `broken` for) `isStatic`. Only a few packages have
the needed `&& !isStatic` in the default value for their parameter.
This commit moves the logic for the default value of these flags into
`systemd.meta.{platforms,badPlatforms}` and evaluates those conditions using
`lib.meta.availableOn`.
This provides three benefits:
1. The default values are set correctly (i.e. including `&& isStatic`)
2. The default values are set consistently
3. The way is paved for any future non-Linux systemd platforms (FreeBSD is
reported to have experimental systemd support)
57 lines
1.5 KiB
Nix
57 lines
1.5 KiB
Nix
{ stdenv
|
|
, lib
|
|
, fetchFromGitHub
|
|
, autoreconfHook
|
|
, ldc
|
|
, installShellFiles
|
|
, pkg-config
|
|
, curl
|
|
, sqlite
|
|
, libnotify
|
|
, withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd
|
|
, systemd
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "onedrive";
|
|
version = "2.4.23";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "abraunegg";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
hash = "sha256-yHpjutZV2u1VhnLxsQIu0NtKnqwtoRn4TM+8tXJ4RNo=";
|
|
};
|
|
|
|
nativeBuildInputs = [ autoreconfHook ldc installShellFiles pkg-config ];
|
|
|
|
buildInputs = [
|
|
curl
|
|
sqlite
|
|
libnotify
|
|
] ++ lib.optional withSystemd systemd;
|
|
|
|
configureFlags = [
|
|
"--enable-notifications"
|
|
] ++ lib.optionals withSystemd [
|
|
"--with-systemdsystemunitdir=${placeholder "out"}/lib/systemd/system"
|
|
"--with-systemduserunitdir=${placeholder "out"}/lib/systemd/user"
|
|
];
|
|
|
|
# we could also pass --enable-completions to configure but we would then have to
|
|
# figure out the paths manually and pass those along.
|
|
postInstall = ''
|
|
installShellCompletion --bash --name ${pname} contrib/completions/complete.bash
|
|
installShellCompletion --zsh --name _${pname} contrib/completions/complete.zsh
|
|
installShellCompletion --fish --name ${pname} contrib/completions/complete.fish
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A complete tool to interact with OneDrive on Linux";
|
|
homepage = "https://github.com/abraunegg/onedrive";
|
|
license = licenses.gpl3Only;
|
|
maintainers = with maintainers; [ srgom peterhoeg bertof ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|