mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 08:33:54 +00:00
eb04659fc2
This was achieved using the following command:
sd 'wrapGAppsHook\b' wrapGAppsHook3 (rg -l 'wrapGAppsHook\b')
And then manually reverted the following changes:
- alias in top-level.nix
- function name in wrap-gapps-hook.sh
- comment in postFixup of at-spi2-core
- comment in gtk4
- comment in preFixup of 1password-gui/linux.nix
- comment in postFixup of qgis/unwrapped-ltr.nix and qgis/unwrapped.nix
- comment in postFixup of telegram-desktop
- comment in postFixup of fwupd
- buildCommand of mongodb-compass
- postFixup of xflux-gui
- comment in a patch in kdePackages.kde-gtk-config and plasma5Packages.kde-gtk-config
- description of programs.sway.wrapperFeatures.gtk NixOS option (manual rebuild)
47 lines
1.5 KiB
Nix
47 lines
1.5 KiB
Nix
{ fetchzip, lib, stdenv, jdk, runtimeShell, glib, wrapGAppsHook3 }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "5.5.3";
|
|
pname = "keystore-explorer";
|
|
src = fetchzip {
|
|
url = "https://github.com/kaikramer/keystore-explorer/releases/download/v${version}/kse-${lib.replaceStrings ["."] [""] version}.zip";
|
|
sha256 = "sha256-oShVfmien4HMpAfSa9rPr18wLu7RN8ZWEZEUtiBHyBs=";
|
|
};
|
|
|
|
# glib is necessary so file dialogs don't hang.
|
|
buildInputs = [ glib ];
|
|
nativeBuildInputs = [ wrapGAppsHook3 ];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/bin
|
|
mkdir -p $out/share/keystore-explorer
|
|
cp -R icons licenses lib kse.jar $out/share/keystore-explorer/
|
|
|
|
# keystore-explorer's kse.sh tries to detect the path of Java by using
|
|
# Python on Darwin; just write our own start script to avoid unnecessary dependencies
|
|
cat > $out/bin/keystore-explorer <<EOF
|
|
#!${runtimeShell}
|
|
export JAVA_HOME=${jdk.home}
|
|
exec ${jdk}/bin/java -jar $out/share/keystore-explorer/kse.jar "\$@"
|
|
EOF
|
|
chmod +x $out/bin/keystore-explorer
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
dontStrip = true;
|
|
dontBuild = true;
|
|
dontConfigure = true;
|
|
|
|
meta = {
|
|
description = "Open source GUI replacement for the Java command-line utilities keytool and jarsigner";
|
|
mainProgram = "keystore-explorer";
|
|
sourceProvenance = with lib.sourceTypes; [ binaryBytecode ];
|
|
license = lib.licenses.gpl3Only;
|
|
maintainers = [ lib.maintainers.numinit ];
|
|
platforms = lib.platforms.unix;
|
|
};
|
|
}
|