mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-25 22:33:43 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
108 lines
2.6 KiB
Nix
108 lines
2.6 KiB
Nix
{
|
|
autoPatchelfHook,
|
|
buildFHSEnv,
|
|
dpkg,
|
|
fetchurl,
|
|
inotify-tools,
|
|
lib,
|
|
stdenvNoCC,
|
|
sysctl,
|
|
writeScript,
|
|
}:
|
|
|
|
let
|
|
pname = "expressvpn";
|
|
clientVersion = "3.52.0";
|
|
clientBuild = "2";
|
|
version = lib.strings.concatStringsSep "." [
|
|
clientVersion
|
|
clientBuild
|
|
];
|
|
|
|
expressvpnBase = stdenvNoCC.mkDerivation {
|
|
inherit pname version;
|
|
|
|
src = fetchurl {
|
|
url = "https://www.expressvpn.works/clients/linux/expressvpn_${version}-1_amd64.deb";
|
|
hash = "sha256-cDZ9R+MA3FXEto518bH4/c1X4W9XxgTvXns7zisylew=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
dpkg
|
|
autoPatchelfHook
|
|
];
|
|
|
|
dontConfigure = true;
|
|
dontBuild = true;
|
|
|
|
unpackPhase = ''
|
|
runHook preUnpack
|
|
dpkg --fsys-tarfile $src | tar --extract
|
|
runHook postUnpack
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mv usr/ $out/
|
|
runHook postInstall
|
|
'';
|
|
};
|
|
|
|
expressvpndFHS = buildFHSEnv {
|
|
inherit pname version;
|
|
|
|
# When connected, it directly creates/deletes resolv.conf to change the DNS entries.
|
|
# Since it's running in an FHS environment, it has no effect on actual resolv.conf.
|
|
# Hence, place a watcher that updates host resolv.conf when FHS resolv.conf changes.
|
|
runScript = writeScript "${pname}-wrapper" ''
|
|
cp /host/etc/resolv.conf /etc/resolv.conf;
|
|
while inotifywait /etc 2>/dev/null;
|
|
do
|
|
cp /etc/resolv.conf /host/etc/resolv.conf;
|
|
done &
|
|
expressvpnd --client-version ${clientVersion} --client-build ${clientBuild}
|
|
'';
|
|
|
|
# expressvpnd binary has hard-coded the path /sbin/sysctl hence below workaround.
|
|
extraBuildCommands = ''
|
|
mkdir -p sbin
|
|
chmod +w sbin
|
|
ln -s ${sysctl}/bin/sysctl sbin/sysctl
|
|
'';
|
|
|
|
# The expressvpnd binary also uses hard-coded paths to the other binaries and files
|
|
# it ships with, hence the FHS environment.
|
|
|
|
targetPkgs =
|
|
pkgs: with pkgs; [
|
|
expressvpnBase
|
|
inotify-tools
|
|
iproute2
|
|
];
|
|
};
|
|
in
|
|
stdenvNoCC.mkDerivation {
|
|
inherit pname version;
|
|
|
|
dontUnpack = true;
|
|
dontConfigure = true;
|
|
dontBuild = true;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p $out/bin $out/share
|
|
ln -s ${expressvpnBase}/bin/expressvpn $out/bin
|
|
ln -s ${expressvpndFHS}/bin/expressvpnd $out/bin
|
|
ln -s ${expressvpnBase}/share/{bash-completion,doc,man} $out/share/
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "CLI client for ExpressVPN";
|
|
homepage = "https://www.expressvpn.com";
|
|
license = licenses.unfree;
|
|
platforms = [ "x86_64-linux" ];
|
|
maintainers = with maintainers; [ yureien ];
|
|
};
|
|
}
|