mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-16 18:53:17 +00:00
9b773fd98a
Cairo is also a dependency now.
/tmp/nix-build-inkscape-0.92.4.drv-0/inkscape-0.92.4/src/display/drawing-context.h:20:10: fatal error: 'cairo.h' file not found
#include <cairo.h>
^~~~~~~~~
1 error generated.
79 lines
2.6 KiB
Nix
79 lines
2.6 KiB
Nix
{ stdenv, fetchurl, pkgconfig, perlPackages, libXft
|
||
, libpng, zlib, popt, boehmgc, libxml2, libxslt, glib, gtkmm2
|
||
, glibmm, libsigcxx, lcms, boost, gettext, makeWrapper
|
||
, gsl, gtkspell2, cairo, python2, poppler, imagemagick, libwpg, librevenge
|
||
, libvisio, libcdr, libexif, potrace, cmake
|
||
, librsvg, wrapGAppsHook
|
||
}:
|
||
|
||
let
|
||
python2Env = python2.withPackages(ps: with ps;
|
||
[ numpy lxml scour ]);
|
||
in
|
||
|
||
stdenv.mkDerivation rec {
|
||
name = "inkscape-0.92.4";
|
||
|
||
src = fetchurl {
|
||
url = "https://media.inkscape.org/dl/resources/file/${name}.tar.bz2";
|
||
sha256 = "0pjinhjibfsz1aywdpgpj3k23xrsszpj4a1ya5562dkv2yl2vv2p";
|
||
};
|
||
|
||
# Inkscape hits the ARGMAX when linking on macOS. It appears to be
|
||
# CMake’s ARGMAX check doesn’t offer enough padding for NIX_LDFLAGS.
|
||
# Setting strictDeps it avoids duplicating some dependencies so it
|
||
# will leave us under ARGMAX.
|
||
strictDeps = true;
|
||
|
||
unpackPhase = ''
|
||
cp $src ${name}.tar.bz2
|
||
tar xvjf ${name}.tar.bz2 > /dev/null
|
||
cd ${name}
|
||
'';
|
||
|
||
postPatch = ''
|
||
patchShebangs share/extensions
|
||
patchShebangs fix-roff-punct
|
||
|
||
# Python is used at run-time to execute scripts, e.g., those from
|
||
# the "Effects" menu.
|
||
substituteInPlace src/extension/implementation/script.cpp \
|
||
--replace '"python-interpreter", "python"' '"python-interpreter", "${python2Env}/bin/python"'
|
||
'';
|
||
|
||
nativeBuildInputs = [ pkgconfig cmake makeWrapper python2Env wrapGAppsHook ]
|
||
++ (with perlPackages; [ perl XMLParser ]);
|
||
buildInputs = [
|
||
libXft libpng zlib popt boehmgc
|
||
libxml2 libxslt glib gtkmm2 glibmm libsigcxx lcms boost gettext
|
||
gsl poppler imagemagick libwpg librevenge
|
||
libvisio libcdr libexif potrace
|
||
|
||
librsvg # for loading icons
|
||
|
||
python2Env perlPackages.perl
|
||
] ++ stdenv.lib.optional (!stdenv.isDarwin) gtkspell2
|
||
++ stdenv.lib.optional stdenv.isDarwin cairo;
|
||
|
||
enableParallelBuilding = true;
|
||
|
||
# Make sure PyXML modules can be found at run-time.
|
||
postInstall = stdenv.lib.optionalString stdenv.isDarwin ''
|
||
install_name_tool -change $out/lib/libinkscape_base.dylib $out/lib/inkscape/libinkscape_base.dylib $out/bin/inkscape
|
||
install_name_tool -change $out/lib/libinkscape_base.dylib $out/lib/inkscape/libinkscape_base.dylib $out/bin/inkview
|
||
'';
|
||
|
||
meta = with stdenv.lib; {
|
||
license = "GPL";
|
||
homepage = https://www.inkscape.org;
|
||
description = "Vector graphics editor";
|
||
platforms = platforms.all;
|
||
longDescription = ''
|
||
Inkscape is a feature-rich vector graphics editor that edits
|
||
files in the W3C SVG (Scalable Vector Graphics) file format.
|
||
|
||
If you want to import .eps files install ps2edit.
|
||
'';
|
||
};
|
||
}
|