mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 00:24:18 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
35 lines
864 B
Nix
35 lines
864 B
Nix
{ lib, runCommand, junicode, texliveBasic }:
|
|
let
|
|
texliveWithJunicode = texliveBasic.withPackages (p: [ p.xetex junicode ]);
|
|
|
|
texTest = { package, tex, fonttype, file }:
|
|
lib.attrsets.nameValuePair "${package}-${tex}-${fonttype}" (
|
|
runCommand "${package}-test-${tex}-${fonttype}.pdf"
|
|
{
|
|
nativeBuildInputs = [ texliveWithJunicode ];
|
|
inherit tex fonttype file;
|
|
} ''
|
|
substituteAll $file test.tex
|
|
HOME=$PWD $tex test.tex
|
|
cp test.pdf $out
|
|
'');
|
|
in
|
|
builtins.listToAttrs (
|
|
lib.mapCartesianProduct texTest
|
|
{
|
|
tex = [ "xelatex" "lualatex" ];
|
|
fonttype = [ "ttf" "otf" ];
|
|
package = [ "junicode" ];
|
|
file = [ ./test.tex ];
|
|
}
|
|
++
|
|
[
|
|
(texTest {
|
|
package = "junicodevf";
|
|
fonttype = "ttf";
|
|
tex = "lualatex";
|
|
file = ./test-vf.tex;
|
|
})
|
|
]
|
|
)
|